;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
;		ＰＩＣ１６Ｆ１８２８　ＢＡＳＩＣ　０１
;
;							2015年12月	Ver1.0	JA0QON
;
;	基本的なサブルーチンを設定済み
;
;
;	ディスプレイ
;		MAX2719 8桁7セグLEDモジュール
;		RC3=DAT(DIN)
;		RC4=LAT(LOAD)
;		RC5=CLK(CLK)
;
;
;		PIC16F1828 32MHZ 内部発振
;
;
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

		LIST	P=PIC16F1828
		INCLUDE	P16F1828.INC

;
;CONFIGURATION WORD 1(ADDRESS:8007H)
;					設定
;bit13		FCMEN	0	Fail-Safe Clock Monitor
;						1=有効,0=無効
;bit12		IESO	0	内部･外部切替スイッチモード
;			________	1=有効,0=無効
;bit11		CLKOUTEN 1	クロック出力イネーブルビット
;						1=無効　RA4I/O使用可
;						0=有効　クロックがCLKPUTピンに出力される
;bit10-9	BOREN	00	ブラウンアウト設定
;						11=有効
;						10=スリープ時以外有効
;			___			00=無効
;bit8		CPD		1	データメモリプロテクション
;			__			1=無効,0=有効
;bit7		CP		1	プログラムメモリプロテクション　
;						1=無効,0=有効
;bit6		MCLRE	0	RA3/MCLRピン選択ビット
;			_____		1=MCLR有効,0=RA3有効(Digital input)
;bit5		PWRTE	0	power_up timer　使います。
;						1=無効,0=有効
;bit4-3		WDTE	00	Watchdog Timer
;						11=有効
;						10=ランニング中に有効、スリープ中は無効
;						01=レジスタによるコントロール
;						00=無効
;bit2-0		FOSC	100	発振器選択ビット
;						111=ECH:外部クロック入力（4-32MHZ)、RA4I/O可
;						110=ECM:外部クロック入力（0.5-4MHZ)、RA4I/O可
;						101=ECL:外部クロック入力（0-0.5MHZ)、RA4I/O可
;						100=INTOSC:内部発振、RA4-RA5I/O可
;						011=EXTRC:外部RC発振、RA4I/O可、RA5不可
;						010=HS：外部発振子、I/O不可
;						001=XT：　〃
;						000=LP：　〃
;
;bit	15 14 13 12 11 10 09 08 07 06 05 04 03 02 01 00
;data    0  0  0  0  1  0  0  1  1  0  0  0  0  1  0  0
;
;
	__CONFIG _CONFIG1,	B'0000100110000100'
;
;CONFIGURATION WORD 2(ADDRESS:8008H)マニュアル52ページ
;					設定
;bit13		LVP		0	低電圧プログラミング設定
;						1=有効
;			_____		0=無効、高電圧必要
;bit12		DEBUG	1	インサーキット･デバッガ モード設定
;						1=無効
;						0=有効、RA0-1をデバッガに使用
;bit11					Unimplemented(read = 1)
;bit10		BORV	0	ブラウンアウト･リセット電圧選択ビット（Vbor参照)
;						1=低電圧で動作
;						0=高電圧で動作
;bit9		STVREN	0	スタック･オーバーフロー･リセット設定
;						1=有効
;						0=無効
;bit8		PLLEN	0	PLL設定
;						1=4xPLL有効
;						0=4xPLL無効
;bit7-5					Unimplemented(read = 1)
;bit4					Reserved (read = 1)
;bit3-2					Unimplemented(read = 1)
;bit1-0		WRT		11	フラッシュメモリ プロテクション設定（EECONレジスタ参照)
;						11=無効
;						10=0h-1FFh有効
;						01=0h-3FFh有効
;						00=0h-7FFh有効
;
;bit	15 14 13 12 11 10 09 08 07 06 05 04 03 02 01 00
;data    0  0  0  1  1  0  0  0  1  1  1  1  1  1  1  1
;
;
	__CONFIG _CONFIG2,	B'0001100011111111'



;		ワークエリア定義
;
;		BANK0	20h-7Fh
;
;		使用していないのもあります
;

;演算引数・戻り値用
hex0		equ		020h		;32ビットバイナリ演算用
hex1		equ		021h		;
hex2		equ		022h
hex3		equ		023h
hexw0		equ		024h		;32ビットバイナリ演算用
hexw1		equ		025h
hexw2		equ		026h
hexw3		equ		027h
;ウエイト用専用ワーク
cnt0		equ		028h		;時間待ちルーチン用専用ワーク
cnt1		equ		029h
cnt2		equ		02ah
cnt3		equ		02bh
;汎用ローカルワーク
tmp0		equ		02ch		;汎用ワーク、その場所限定
tmp1		equ		02dh		;移動した場合、破壊されること有
;機能専用広域ワーク
FLG			equ		02eh		;8桁7セグLED表示設定フラグ
MODE		equ		02fh		;実行モード設定フラグ
DSPM		equ		030h		;ディスプレイモード スイッチフラグ
;A/Dコンバータ用専用ワーク
ADM0		equ		031h		;ADC下位データ
ADM1		equ		032h		;ADC上位データ
ADM2		equ		033h		;ADC保存過去データ
;DDS用広域ワーク
FRQ0		equ		034h		;32ビットDDS周波数データ
FRQ1        equ     035h        ;
FRQ2		equ		036h		;
FRQ3		equ		037h		;
TBAL        equ     038h        ;参照テーブル先頭アドレス下位8ビット
TBAH        equ     039h        ;同上位8ビット
;BCD用広域ワーク
digit12     equ     03ah        ;BCD変換出力1，2桁
digit34     equ     03bh		;BCD変換出力3，4桁
digit56     equ     03ch        ;BCD変換出力5，6桁
digit78     equ     03dh        ;BCD変換出力7，8桁
digit9A     equ     03eh        ;BCD変換出力9，10桁
bcdw0		equ		03fh		;BCD補正処理ワーク
bcdw1		equ		040h
;汎用広域ワーク
wrk0		equ		041h        ;演算用汎用ワーク
wrk1		equ		042h
shift       equ     043h        ;ビットシフト用ワーク
blk			equ		044h		;ゼロブランキング制御フラグ
colum		equ		045h		;現在の桁位置
colw0		equ		046h		;桁位置処理ワーク
colw1		equ		047h		;
;8桁7セグLED専用広域ワーク
CMD0		equ		048h		;コマンドパケット下位8ビット
CMD1		equ		049h		;コマンドパケット上位8ビット
DBUF0		equ		04ah		;SPI送信データ編集用バッファ
DBUF1		equ		04bh
DBUF2		equ		04ch
DBUF3		equ		04dh
DBUF4		equ		04eh
DBUF5		equ		04fh
DBUF6		equ		050h
DBUF7		equ		051h
;ロータリーエンコーダ専用ワーク
REDAT       equ     052h        ;ロータリーエンコーダ・ビットデータ
RESP0       equ     053h        ;変化ステップ量 下位バイト
RESP1		equ		054h		;
RESP2		equ		055h		;
rew0        equ     056h        ;専用ワーク
rew1        equ     057h        ;専用ワーク
;メインループ用広域ワーク
FDA0        equ     058h		;32ビット アップダウン カウンタ
FDA1        equ     059h		;基本動作周波数用
FDA2		equ     05ah		;
FDA3		equ     05bh		;
FDB0		equ		05ch		;DDS用動作周波数
FDB1		equ		05dh		;
FDB2		equ		05eh		;
FDB3		equ		05fh		;
IFQ0		equ     060h		;中間周波数用差分データ
IFQ1		equ     061h		;
IFQ2		equ     062h		;
IFQ3		equ     063h		;

;

;
			ORG		0h			;リセットベクタ
			goto	init
			ORG		04h			;割り込みベクタ

;
;		割込み処理ルーチン
;
;		割込み発生から割込みベクタまで3サイクル程度（同期割込み）
;		FSRxはコアレジスタなので、自動で PUSH-POPされる
;		よって、割り込み終了後、元の設定値に戻る
;
INT
;
INTOUT
;
			retfie				;


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
;			PIC16F1828　イニシャライズ
;
;		OSCCON(BANK1　099H)
;			bit7	SPLLEN	ソフトウエアPLL設定ビット
;							1 = 4xPLL有効
;							0 = 4xPLL無効(リセット後)
;			＊コンフィグレーションワードPLLEN=1の時、この設定は無視される。
;			bit6-3	IRCF	内部発振器クロック選択ビット
;							000x = 31KHZ LF
;							0010 = 31.25KHZ MF
;							0011 = 31.25KHZ HF
;							0100 = 62.5KHZ MF
;							0101 = 125KHZ MF
;							0110 = 250KHZ MF
;							0111 = 500KHZ MF（デフォルト）
;							1000 = 125kHZ HF
;							1001 = 250kHZ HF
;							1010 = 500kHZ HF
;							1011 = 1MHZ HF
;							1100 = 2MHZ HF
;							1101 = 4MHZ HF
;							1110 = 8MHZ or 32MHZ HF
;							1111 = 16MHZ HF
;			bit2			Unimplemented
;			bit1-0	SCS		システムクロック選択ビット
;							1x = 内部発振器
;							01 = タイマ1発振器
;							00 = FOSCで指定された発振器(リセット後)
;			(注)詳細はマニュアルあるいは当局HP内解説を参照
;							HF=HFINTOSC（16MHZ)
;							MF=MFINTOSC(500KHZ)
;							LF=LFINTOSC(32KHZ)
;
;
;			32MHZ内部発振設定
;		コンフィグレーションワード1		FOSC=100
;		OSCCON				SCS=00
;		OSCCON				IRCF=1110
;		OSCCON				SPLLEN=1(#1)
;		コンフィグレーションワード2		PLLEN=1(#1)
;						(#1)設定はどちらかでOKだが、PLLEN=1とすると、
;							OSCCONのSPLLEN=0の設定は無効となる。
;							また、8MHZのHFINTOSCは選択の余地が無い。
;
;		各ポートのデジタル入出力は、TTL入力、CMOS出力が基本
;		PORTA(BANK0　00CH）
;			bit7-6	Unimplemented(read=0)
;			bit5	RA5		デジタルI/O
;			bit4	RA4		デジタルI/O、アナログ入力
;			bit3	RA3		デジタルInputのみ(TTL)
;			bit2	RA2		デジタルI/O（CMOSシュミット）、アナログ入力
;			bit2	RA1		デジタルI/O、アナログ入力
;			bit0	RA0		デジタル･アナログI/O,DAコンバータ出力
;
;		PORTB(BANK0　00DH）
;			bit7-6	RB7-6	デジタルI/O
;			bit5-4	RB5-4	デジタルI/O、アナログ入力
;			bit3-0	Unimplemented(read=0)
;
;		PORTC(BANK0　00EH）
;			bit7-6	RC7-6	デジタルI/O、アナログ入力
;			bit5-4	RC5-4	デジタルI/O
;			bit3	RC3-0	デジタルI/O、アナログ入力
;
;		TRISA(BANK1　08CH)
;			bit7-6	Unimplemented(read=0)
;			bit5-4	RA5-4	1=入力、0=出力
;			bit3	RA3		常に1
;			bit2	RA2-0	1=入力、0=出力
;
;		TRISB(BANK1　08DH)
;			bit7-6	Unimplemented(read=0)
;			bit5-4	RB7-4	1=入力、0=出力
;
;		TRISC(BANK1　08EH)　マニュアル130ページ
;			bit7-6	Unimplemented(read=0)
;			bit5-4	RA5-0	1=入力、0=出力
;
;		LATA(BANK2　10CH)
;			bit7-6	Unimplemented(read=0)
;			bit5-4	RA5-4	出力データ保持
;			bit3	Unimplemented(read=0)
;			bit2	RA2-0	出力データ保持
;			（このラッチデータはTRISAレジスタ設定で各ピンに反映される）
;
;		LATB(BANK2　10DH)
;			bit7-4	RAB7-4	出力データ保持
;			bit3-0	Unimplemented(read=0)
;			（このラッチデータはTRISBレジスタ設定で各ピンに反映される）
;
;		LATC(BANK2　10EH)
;			bit7-6	Unimplemented(read=0)
;			bit5-0	RA5-4	出力データ保持
;			（このラッチデータはTRISCレジスタ設定で各ピンに反映される）
;
;
;		ANSELA(BANK3　18CH)
;			bit7-5	Unimplemented(read=0)
;			bit4	ANSA3/RA4	アナログ/デジタル選択ビット
;								1=アナログ入力
;								0=デジタルI/O
;			bit3	Unimplemented(read=0)
;			bit2-0	ANA2-0/RA2-0アナログ/デジタル選択ビット
;								1=アナログ入力
;								0=デジタルI/O
;			＊デフォルトでは、すべて1(アナログ入力)となっている
;
;		ANSELB(BANK3　18DH)
;			bit7-4	ANSC3-0/RC3-0　アナログ/デジタル選択ビット
;								1=アナログ入力
;								0=デジタルI/O
;			bit3-0	Unimplemented(read=0)
;			＊デフォルトではアナログ入力となっている
;
;		ANSELC(BANK3　18EH)　マニュアル131ページ
;			bit7-4	Unimplemented(read=0)
;			bit3-0	ANSC3-0/RC3-0　アナログ/デジタル選択ビット
;								1=アナログ入力
;								0=デジタルI/O
;			＊デフォルトではアナログ入力となっている
;
;		WPUA(BANK4　20CH)　ポートAプルアップ設定ビット
;			bit7-6	Unimplemented(read=0)
;			bit5-0			1=PORTA各ビットプルアップ有効
;					 _____	0=PORTA各ビットプルアップ無効
;					*WPUENビットが有効の時のみ、設定有効となる。
;
;		WPUB(BANK4　20DH)　ポートBプルアップ設定ビット
;			bit7-4			1=PORTB各ビットプルアップ有効
;					 _____	0=PORTB各ビットプルアップ無効
;			bit3-0	Unimplemented(read=0)
;					*WPUENビットが有効の時のみ、設定有効となる。
;
;		WPUC(BANK4　20EH)　ポートCプルアップ設定ビット
;			bit7-0			1=PORTC各ビットプルアップ有効
;					 _____	0=PORTC各ビットプルアップ無効
;					*WPUENビットが有効の時のみ、設定有効となる。
;
;		INLVLA(BANK7　38CH)　ポートA入力レベル設定レジスタ
;			bit7-6	Unimplemented(read=0)
;			bit5-0	RA5-0	ST/TTL選択ビット
;								1=シュミットトリガー(ST)入力
;								0=TTL入力
;
;		INLVLB(BANK7　38DH)　ポートB入力レベル設定レジスタ
;			bit7-4	RB7-4	ST/TTL選択ビット
;								1=シュミットトリガー(ST)入力
;								0=TTL入力
;			bit3-0	Unimplemented(read=0)
;
;		INLVLB(BANK7　38EH)　ポートC入力レベル設定レジスタ
;			bit7-0	RC7-0	ST/TTL選択ビット
;								1=シュミットトリガー(ST)入力
;								0=TTL入力
;
;	ADCON0レジスタ(BANK1　09DH)
;		bit7	Unimplemented(read=0)
;		bit6-2	CHS		アナログ入力チャンネル選択ビット
;						00000 = AN0/RA0
;						00001 = AN1/RA1
;						00010 = AN2/RA2
;						00011 = AN3/RA4
;						00100 = AN4/RC0
;						00101 = AN5/RC1
;						00110 = AN6/RC2
;						00111 = AN7/RC3
;						01000 = AN8/RC6
;						01001 = AN9/RC7
;						01010 = AN10/RB4
;						01011 = AN11/RB5
;						11101 = 温度インジケータ
;						11110 = DAC出力
;						11111 = FVRバッファ1出力
;		bit1	GO/DONE	A/D変換ステータスビット
;						1=変換開始指令（１にすると変換動作開始）
;						0=変換完了(変換完了すると０になる）
;		bit0	ADON	A/D変換ステータスビット
;						1=A/Dコンバータ動作
;						0=A/Dコンバータ停止
;
;	ADCON1レジスタ(BANK1　09EH)
;		bit7	ADFM	変換結果格納指定
;						1=右詰
;						0=左詰め
;		bit6-4	ADCS	A/D変換クロック選択ビット
;						000	= Fosc/2
;						001 = Fosc/8
;						010 = Fosc/32
;						011 = Frc
;						100 = Fosc/4
;						101 = Fosc/16
;						110 = Fosc/64
;						111 = Frc
;		bit3	Unimplemented(read=0)
;		bit2	ADNREF	参照負電圧指定
;						0 = VSS
;						1 = 外部VREF- (RA0)
;		bit1-0	ADPREF	参照正電圧指定
;						00 = VDD
;						01 = Reserved
;						10 = 外部VREF+ (RA1)
;						11 = 内部FVRモジュール
;
;		FVRCONレジスタ(BANK2　117H)
;			bit7	FVREN	FVRイネーブルビット
;							1有効、0無効
;			bit6	FVRRDY	FVR準備フラグビット(#1)書込み不可
;							1使用可能、0使用不可能あるいは禁止されている
;			bit5	TSEN	温度表示器イネーブルビット
;							1有効、0無効
;			bit4	TSRNG	温度表示器測定レンジ選択ビット
;							1=High Range:Vout=VDD-4VT
;							0=Low Range:Vout=VDD-2VT
;			bit3-2	CDAFVR	コンパレータとDACへのFVR電圧選択ビット
;							00 = FVR出力OFF
;							01 = FVR出力 1x(1.024V)
;							10 = FVR出力　2x(2.048V)#2
;							11 = FVR出力　4x(4.096V)#2
;			bit1-0	ADFVR	ADCへのFVR電圧選択ビット
;							00 = FVR出力OFF
;							01 = FVR出力 1x(1.024V)
;							10 = FVR出力　2x(2.048V)#2
;							11 = FVR出力　4x(4.096V)#2
;
;							#1)12F1824/16F1828では常に"1"
;							#2)FVR電圧出力はVDDを超える事は出来ない
;
;
;	OPTION_REG(BANK1　095H)
;				_____
;		bit7=1	WPUEN	プルアップ グローバル設定ビット
;						0=有効,1=無効
;		bit6=0	INTEDG	INTピン割り込み信号エッジ↑
;						1=↑
;						0=↓
;		bit5=1	TMR0CS	TMR0クロックソース選択ビット
;						1=外部入力RA2/T0CKI
;						0=内部システムクロック(Fosc/4)
;		bit4=0	TMR0SE	TMR0ソースエッジ選択ビット
;						1=RA2/T0CKIピンが↑の時インクリメント
;						0=RA2/T0CKIピンが↓の時インクリメント
;		bit3=0	PSA		プリスケーラ割当ビット
;						1=WDT
;						0=TMR0
;		bit2-0	PS		プリスケーラ分周比
;						000 1/2
;						001	1/4
;						010	1/8
;						011	1/16
;						100	1/32
;						101	1/64
;						110	1/128
;						111	1/256
;
;	CPSCON0(BANK0　01EH)
;		bit7=0	CPSON	CPSモジュール･イネーブルビット
;						1=有効
;						0=無効
;		bit6=0	CPSRM	静電容量式センシング参照電圧モードビット
;						1=CPSモジュールをHIレンジに設定
;						　　オシレータの参照電圧にDACとFVRを使用
;						0=CPSモジュールをLOWレンジに設定
;						　　オシレータ内蔵の参照電圧を使用
;		bit5-4	Unimplemented(read=0)
;		bit3-2	CPSRNG	静電容量式センシング電流レンジビット
;						CPSRM=0の場合
;						00=オシレータはOFF
;						01=オシレータをLOWレンジに設定、充放電電流は0.1uA
;						10=オシレータをMediumレンジに設定、充放電電流は1.2uA
;						11=オシレータをHighレンジに設定、充放電電流は18uA
;						CPSRM=1の場合
;						00=オシレータはON、ノイズ検出モード
;							充放電電流は供給されない
;						01=オシレータをLOWレンジに設定、充放電電流は9uA
;						10=オシレータをMediumレンジに設定、充放電電流は30uA
;						11=オシレータをHighレンジに設定、充放電電流は100uA
;		bit1=0	CPSOUT	静電容量式センシングオシレータ ステータスビット
;						1=オシレータが電流をソース（ピンから電流を出力）
;						0=オシレータが電流をシンク（ピンから電流を入力）
;		bit0=0	T0XCS	Timer0外部クロック源選択ビット
;						TMR0CS=1の場合
;						コア/Timer0モジュールのどの外部クロックからTimer0に
;						クロックを供給するかをTOXCSビットで制御する
;						1=Timer0のクロック源に静電容量式センシングオシレータ使用
;						0=Timer0のクロック源にT0CKIピンを使う
;						TMR0CS=0の場合
;						Timer0のクロック源にコア/Timer0モジュールで制御する
;						すなわち、Fosc/4
;
;
;		DACCON0レジスタ(BANK2　11AH)　
;		bit7	DACEN	DACイネーブルビット　P156 Fig17-1参照
;						1=許可
;						0=禁止
;		bit6	DACLPS	電圧指定
;						1=DAC出力電圧は+sourecと同等
;						0=DAC出力電圧は-sourceと同等
;		bit5	DACOE	DAC電圧出力イネーブルビット
;						1=DAC出力電圧をDACOUTピンに接続される
;						0=DAC出力電圧はDACOUTピンに接続されない
;		bit4	Un		Read as '0'
;		bit3-2	DACPSS	DAC Vsource+接続選択ビット
;						00 = VDD
;						01 = VREF+ピン(RA1)
;						10 = FVRバッファ2出力
;						11 = 使用不可
;		bit1-0	Un		Read as '0'
;
;
;
;
;	SSP1CON1	SSP制御レジスタ１	BSR=4
;		bit7	WCOL：書込みコリジョン検出ビット
;				マスタの場合
;				1=I2Cの送信開始条件が無効の時にSSP1BUFレジスタへ書込みが行われた
;				0=問題無
;				スレーブの場合
;				1=前のワードの送信中にSSP1BUFレジスタへの書き込みが行われた
;				0=問題無
;					*ソフトウエアでクリアする必要あり
;		bit6	SSP1OV：受信オーバーフロー インジケータービット(注1)
;				1=オーバーフロー発生
;				2=問題無
;					*ソフトウエアでクリアする必要あり
;		bit5	SSP1EN：同期シリアルポートイネーブルビット
;				1=シリアルポート有効(注2)
;				0=シリアルポート無効、I/Oポート使用可
;		bit4	CKP：クロック極性選択ビット
;				1=クロックを有効化
;				0=クロックをLOWに保持（クロックストレッチ）
;					*マスタモードでは使用しない
;		bit3-0  SSP1M：同期シリアルポート モード選択ビット
;				0110=スレーブモード、7ビットアドレス
;				0111=スレーブモード、10ビットアドレス
;				1000=マスターモード、クロック=FOSC/(4*SP1ADD+1))(注3)
;				1011=ファームウエア制御のマスターモード（スレーブアイドル）
;				1110=スレーブモード、7ビットアドレス、
;					スタートビットとストップビットの割込み有効
;				1111=スレーブモード、10ビットアドレス、
;					スタートビットとストップビットの割込み有効
;
;		注1)マスターモードの場合、新たな送受信はSSP1BUFへの書込みによって
;			開始するため、オーバーフロービットはセットされない
;		注2)SDAピンとSCLピンは入力としてTRIS設定
;		注3)SP1ADDの値、0,1,2はサポートされない
;
;	SSP1CON2	SSP制御レジスタ２
;		bit7	GCEN：ジェネラルコールイネーブルビット
;				1=SSP1SRでGCアドレス(00H)を受信した時の割込みを有効にする
;				0=GCアドレスを無効にする
;		bit6	ACKSTAT：肯定応答(ACK)ステータスビット
;				1=ACK受信した
;				0=ACK受信していない
;		bit5	ACKDT：ACKデータビット（受信モード）
;				1=ACKしない
;				0=ACKあり
;		bit4	ACKEN：ACKシーケンス イネーブルビット（マスタ受信モード）（注1）
;				1=ACKシーケンスを開始し、ACKDTビットを送信する
;				0=ACKシーケンスをアイドルにする
;		bit3	RCEN：受信イネーブルビット（マスターモードのみ）（注1）
;				1=受信モードを有効にする
;				0=受信をアイドルにする
;		bit2	PEN：ストップ条件イネーブルビット（注1）
;				SCK解放制御
;				1=ストップ条件を開始する、ハードウエアによって自動でクリアされる
;				0=ストップ条件をアイドルにする
;		bit1	RSEN：反復スタート条件イネーブルビット（注1）
;				1=反復スタート条件を開始する
;					ハードウエアによって自動でクリアされる
;				0=反復スタート条件をアイドルにする
;		bit0	SEN：スタート条件イネーブルビット（注1）
;				マスターモードの場合
;				1=スタート条件を開始する、ハードウエアによって自動でクリアされる
;				0=スタート条件をアイドルにする
;
;		注1）I2Cモジュールがアイドルで無い場合、これらのビットはセットされず、
;			 SSP1BUFに書き込まれない場合がある（SSP1BUFへの書込み無効）
;
;	SSP1CON3	SSP1制御レジスタ３
;		bit7	ACKTIM：肯定応答(ACK)タイムステータスビット（注1）
;				1=ACKシーケンスを実行中。
;				　SCLクロックの8番目の立下りエッジでセットされる
;				0=ACKシーケンスではない。
;				　SCLクロックの9番目の立上がりエッジでクリアされる
;		bit6	PCIE：ストップ条件割込みイネーブルビット
;				1=ストップ条件検出時の割込みを有効にする
;				0=ストップ条件検出時の割込みを無効にする
;		bit5	SCIE：スタート条件割込みイネーブルビット
;				1=スタート／リスタート条件検出時の割込みを有効にする
;				0=スタート条件検出時の割込みを無効にする
;		bit4	BOEN：バッファ上書きイネーブルビット
;				1=SSP1BUFは更新され、受信したアドレス／データバイトに対して
;				　ACK信号が生成される。
;				　BFビットが0の場合のみSSP1OVビットの状態を無視する。
;				0=SSP1OVがクリアされている時のみSSP1BUFが更新される
;				*マスタモードの場合、このビットは無視される
;		bit3	SDAHT：SDAホールド時間の選択ビット
;				1=SDAのホールド時間はSCLの立下りエッジから最小300ns
;				0=SDAのホールド時間はSCLの立下りエッジから最小100ns
;		bit2	SBCDE：スレーブモードのバスコリジョン検出イネーブルビット
;				1=スレーブバスコリジョン割込みを有効にする
;				0=スレーブバスコリジョン割込みを無効にする
;		bit1	AHEN：アドレスホールドイネーブルビット（スレーブモードのみ）
;				1=一致受信アドレスバイトのSCLの8番目の立下りエッジ後、SSP1CON1
;				　レジスタのCKPビットをクリアし、SCLがLOWに保持される
;				0=アドレスホールド機能を無効にする
;		bit0	DHEN：データホールドイネーブルビット（スレーブモードのみ）
;				1=受信データバイトのSCLの8番目の立下りエッジ後、スレーブハードウ
;				エアがSSP1CON1レジスタのCKPビットをクリアし、SCLがLOWに保持される
;				0=データホールド機能を無効にする
;		*注1）ACKTIMステータスビットがアクティブになるのは、AHENビットまたは、
;             DHENビットがセットされている場合のみ
;
;	SSP1MSK		SSP1マスクレジスタ
;		bit7-1	MSK：マスクビット
;				1=受信アドレスbitnをSSP1ADD(n)と比較して、I2Cアドレス一致を検出
;				0=受信アドレスbitnをI2Cアレス一致の検出に使わない
;		bit0	I2Cスレーブモードのマスクビット、10ビットアドレス
;				I2Cスレーブモード、10ビットアドレス（SSP1M3-0=0111または1111)
;				1=受信アドレスbit0をSSP1ADD(0)と比較して、I2Cアドレス一致を検出
;				0=受信アドレスbit0をI2Cアレス一致の検出に使わない
;				*スレーブモード、7ビットアドレスでは、このビットは無視される
;
;	SSP1ADD		MSSP1アドレス／ボーレートジェネレータ
;				マスターモードの場合
;		bit7-0	ADD：ボーレートクロック分周ビット（(ADD(7-0)+1)*4）/FOSC
;				スレーブモードの場合
;		bit7-1	ADD：7ビットのアドレス
;		bit0	未使用
;		*10ビットアドレスモードでの状態は割愛します
;
;	SSP1STAT	SSP1ステータスレジスタ
;		bit7	SMP：スルーレート制御
;				1=スルーレート制御の標準速度モード(100KHZ,1MHZ)を無効にする
;				0=スルーレート制御の高速モード(100KHZ)を有効にする
;		bit6	CKE：SMBus仕様互換入力
;				1=しきい値がSMBus仕様に準拠する入力
;				0=無効
;		bit5	D_NOT_A：データ/アドレスビット
;				1=最後に送受信したバイトがデータ
;				0=最後に送受信したバイトがアドレス
;		bit4	P：ストップビット
;				1=最後にストップビットが検出された事を示す
;				0=最後にストップビットが検出されなかった事を示す
;		bit3	S：スタートビット
;				1=最後にスタートビットが検出された事を示す
;				0=最後にスタートビットが検出されなかった事を示す
;		bit2	R_NOT_W：READ/WRITEビット情報
;				スレーブモード
;				1=読み出し
;				0=書込み
;				マスタモード
;				1=送信動作中
;				0=送信動作中で無い
;		*このビットとSEN,RSEN,PEN,RCEN,ACKENのどれかをORするとMSSP1がアイドル中
;		 かどうかが判る
;		bit1	UA：交信アドレスビット（10ビットアドレスモードのみ）
;				1=アドレスの更新が必要
;				0=アドレスの更新が不要
;		bit0	BF：バッファフル ステータスビット
;				受信
;				1=受信が完了、SSP1BUFがフルである
;				0=受信が完了していない、SSP1BUFがエンプティ
;				送信
;				1=データ送信中(ACK及びｽﾄｯﾌﾟﾋﾞｯﾄを含まない)SSP1BUFはフル
;				0=データ送信完了(ACK及びｽﾄｯﾌﾟﾋﾞｯﾄを含まない)SSP1BUFはエンプティ
;
;
;
;		INTCONレジスタ(#2)　コア　00BH
;			bit7	GIE		全割込制御
;							1許可、0禁止
;			bit6	PEIE	周辺装置割込制御
;							1許可、0禁止
;			bit5	TMR0IE	タイマ0割込許可制御
;							1許可、0禁止
;			bit4	INTE	RA2外部割込許可制御
;							1許可、0禁止
;			bit3	IOCIE	I/Oポート状態変化割込許可制御
;							1許可、0禁止
;			bit2	TMR0IF	タイマ0割込みフラグ(#1)
;							1オーバーフロー
;							0オーバーフローなし
;			bit1	INTF	RA2外部割込みフラグ(#1)
;							1割込み発生
;							0割込み発生なし
;			bit0	IOCIF	I/Oポート状態変化割込フラグ(#1)
;							1割込発生
;							0割込無
;
;							#1)ソフトウエアでリセット必要
;							#2)初期値=0なので、初期設定で0設定する必要は無い
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

init
;			各レジスタ初期設定(PIC16F1828)
			movlb	0h			;BANK0
			movlw	000h		;00000000B
			movwf	INTCON		;全割込みOFF
			;クロック設定
			movlb	01h			;BANK１に切替
			movlw	0f0h		;1111000B
			movwf	OSCCON		;内部発振器は8MHZに設定
								;4xPLL=ON
			;I/Oポート初期化
			movlb	0h			;BANK0
			clrf	PORTA		;Init PORT
			clrf	PORTB
			clrf	PORTC
			movlb	02h			;BANK2
			clrf	LATA		;出力ラッチレジスタ
			clrf	LATB
			clrf	LATC
			movlb	03h			;BANK3
			movlw	010h		;10H=00010000
			movwf	ANSELA		;RA4アナログ、RA0-3,5デジタルI/O
			clrf	ANSELB		;RB4-7デジタルI/O
			clrf	ANSELC		;RC0-7デジタルI/O
			movlb	01h			;BANK1
			movlw	0ffh		;
			movwf	TRISA		;RA0-5入力
			movlw	0ffh
			movwf	TRISB		;RB4-7入力
			movlw	0c7h		;C7H＝11000111B
			movwf	TRISC		;RC3-RC5出力、RC0-RC2,RC6-RC7入力

			;TMR0およびプルアップ設定
			movlb	01h			;BANK1
			movlw	0a7H		;10100111B
			movwf	OPTION_REG	;プルアップOFF
								;割込みエッジ↓
								;クロックソース外部
								;TMR0カウントエッジ↓
								;プリスケーラ割当→TMR0
								;プリスケーラ分周1/256にセット

			;ADC
			movlb	01h			;BANK1
			movlw	0E0h		;11100000B
			movwf	ADCON1		;10bit変換、左詰め、基準電圧VDD
								;ADCクロック　Fosc/64=2us(32MHZ)

			;FVR
;			movlb	02h			;BANK2
;			movlw	082h		;10000010B
;			movwf	FVRCON		;FVRイネーブル
								;DACとCPSはOFF
								;ADCに4.096V

;			設定終了
			movlb	0h


;
;			MAX2719コマンド一覧
;
;	Bモード（デコード有）アドレッシング
;		上位	下位（D15-D0の16ビット)
;		x0H	xxH		NOP
;		x1H	00H-07H	0桁0-9表示（ドット無）
;		x1H	80H-87H	0桁0-9表示（ドット有）
;		x1H	*0H-*7H	*bit7=1でドット有、bit4-6は何でもいい
;		x1H	F0H-F7H	0桁0-9表示（ドット有）
;
;		x2H	**H-**H	1桁、下位7ビットは上記と同じ
;		x3H	**H-**H	2桁、下位7ビットは上記と同じ
;		x4H	**H-**H	4桁、下位7ビットは上記と同じ
;		x5H	**H-**H	5桁、下位7ビットは上記と同じ
;		x6H	**H-**H	6桁、下位7ビットは上記と同じ
;		x7H	**H-**H	7桁、下位7ビットは上記と同じ
;		x8H	**H-**H	8桁、下位7ビットは上記と同じ
;
;	機能設定
;		x9H	**H		デコードモードレジスタ設定
;			00H		7-0桁デコード無(初期設定値)
;			01H		0桁デコード有、7-1桁デコード無
;		xAH	**H		輝度レジスタ設定
;			x0H		1/32(初期設定値)
;			x1H		3/32
;			x2H		5/32
;			x3H		7/32
;			x4H		9/32
;			x5H		11/32
;			x6H		13/32
;			x7H		15/32
;			x8H		17/32
;			x9H		19/32
;			xAH		21/32
;			xBH		23/32
;			xCH		25/32
;			xDH		27/32
;			xEH		29/32
;			xFH		31/32
;
;		xBH	**H		スキャンリミットレジスタ設定（注1）
;			x0H		0桁目のみ(初期設定値)
;			x1H		0&1桁
;			x2H		012桁
;			x3H		0123桁
;			x4H		01234桁
;			x5H		012345桁
;			x6H		0123456桁
;			x7H		01234567桁
;
;		xCH	**H		シャットダウンレジスタ設定
;			x0H		シャットダウンモード(初期設定値)
;			x1H		ノーマルオペレーションモード
;
;		xFH	**H		ディスプレイテストレジスタ設定
;			x0H		ノーマルオペレーションモード(初期設定値)
;			x1H		ディスプレイテストモード
;
;   コードBフォントの使用方法
;		DBUFx　	各桁バッファ データフォーマット（Bモードに適用）
;		bit0-3	表示する十進数値データ	0H-9H→0-9(注2)
;				0AH→-、0BH→E、OCH→H、0DH→L、0EH→P
;				0FH=Blank(注3)
;		bit4	不使用
;		bit5	不使用
;		bit6	不使用
;		bit7    ドット表示	0=OFF、1=ON
;
;		注1）基本的に8桁表示設定で使用するのが良いと思われる
;		注2）表示数値データはMAX2719内部でLED表示ビットデータに変換されます
;		注3）ブランク命令はa-gセグメントのみ有効、DPセグメントには適応されない
;

;			MAX2719イニシャライズ

			call	wait1s      ;MAX2719電源投入安定化待ち
			movlw	0fh			;ディスプレイテストレジスタアドレス
			movwf	CMD1
			movlw	01h
			movwf	CMD0		;テストモード
			call	SEND_CMD
			call	wait100m

			movlw	0fh			;ディスプレイテストレジスタアドレス
			movwf	CMD1
			clrf	CMD0		;ノーマルオペレーション
			call	SEND_CMD

			movlw	0bh			;スキャンレジスタアドレス
			movwf	CMD1
			movlw	07h			;8桁表示セット
			movwf	CMD0
			call	SEND_CMD

			movlw	0ah			;輝度レジスタアドレス
			movwf	CMD1
			movlw	07h			;輝度設定　15/32
			movwf	CMD0
			call	SEND_CMD

			movlw	09h			;デコードモードレジスタアドレス
			movwf	CMD1
			movlw	0ffh		;8桁Bモード
			movwf	CMD0
			call	SEND_CMD
			call	BRKL		;全表示ブランク

			movlw	0ch			;シャットダウンモードレジスタアドレス
			movwf	CMD1
			movlw	01h			;ノーマルモードへ移行
			movwf	CMD0
			call	SEND_CMD
			call	wait100m	;モード安定化待ち

;			初期値セット
			clrf    hex0
			clrf    hex1
			clrf    hex2
			clrf    hex3
			clrf    FDA0
			clrf    FDA1
			clrf    FDA2
			clrf    FDA3
			movlw	04fh		;01001111b
			movwf	FLG			;8桁表示、4,7桁ドット表示指定
								;ゼロブランキングする


;
;		メインループ
;
;

coldst
			movlw	04fh		;flg=01001111B
			movwf	FLG			;8桁、ゼロブランキングON
								;4,7桁ドット有

mloop		;メインループ
			call	BCD
			call	SETBUF		;データ整理
			call	PUTL		;モジュールに送信
			call	wait100m
			
			incf	hex0,F
			btfss	STATUS,Z	;桁上がりか？
			goto	mloop

			incf	hex1,F
			btfss	STATUS,Z
			goto	mloop

			incf	hex2,F
			btfss	STATUS,Z
			goto	mloop

			incf	hex3,F
			btfss	STATUS,Z
			goto	mloop

			clrf	hex0
			clrf	hex1
			clrf	hex2
			clrf	hex3
			goto	mloop



;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
;
;			Ａ／Ｄ変換サブルーチン
;
;		アナログ入力ポート		RA4/AN3
;		結果格納方法		右詰め/10bit取得
;		出力データ			ADM0(1/8、つまり7bitに変換される)
;
;	ADCON0レジスタ(BANK1　09DH)
;		bit7	Unimplemented(read=0)
;		bit6-2	CHS		アナログ入力チャンネル選択ビット
;						00000 = AN0/RA0
;						00001 = AN1/RA1
;						00010 = AN2/RA2
;						00011 = AN3/RA4
;						00100 = AN4/RC0
;						00101 = AN5/RC1
;						00110 = AN6/RC2
;						00111 = AN7/RC3
;						01000 = AN8/RC6
;						01001 = AN9/RC7
;						01010 = AN10/RB4
;						01011 = AN11/RB5
;						11101 = 温度インジケータ
;						11110 = DAC出力
;						11111 = FVRバッファ1出力
;		bit1	GO/DONE	A/D変換ステータスビット
;						1=変換開始指令（１にすると変換動作開始）
;						0=変換完了(変換完了すると０になる）
;		bit0	ADON	A/D変換ステータスビット
;						1=A/Dコンバータ動作
;						0=A/Dコンバータ停止
;
;
;		出力			ADM0	旧データ
;						ADM1	新データ
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;


;			VRによる分電圧取得
GET_ADC
			movlb	01h
			movlw	0Dh			;00001101b
								;左詰め、基準電圧VDD、
								;AN3(RA4)選択、ADON_ON
			movwf	ADCON0		;電圧サンプリング開始
			call	w10u		;サンプリング電圧安定化待ち
			call	w10u
			movlb	01h
			bsf		ADCON0,GO	;A/D変換開始指令
aloop
			btfsc	ADCON0,GO	;A/D変換完了待ち
			goto	aloop		;GO=0ならば次へ
			bcf		ADCON0,ADON	;A/DコンバータOFF

			movf	ADRESH,W	;データ上位2ビット
			movlb	0h
			movwf	ADM1
			movlb	01h
			movf	ADRESL,W	;データ下位8ビット
			movlb	0h
			movwf	ADM0
			retlw	0h



;
;		表示データバッファのセッティング
;
;	入力データ		5バイト(10桁分)BCD　この内容は保存される
;				digit12
;				digit34
;				digit56
;				digit78
;				digit9A（表示されない）
;
;	表示桁		colum　この内容は保存される
;
;	入力制御フラグ	FLG　この内容は保存される
;	　2桁表示指令		FLG=xxxxx001
;	　4桁表示指令		FLG=xxxxx011
;	　6桁表示指令		FLG=xxxxx101
;	　8桁表示指令		FLG=xxxxx111
;	　ゼロブランキング	FLG=xxxx0xxx　
;						bit3=0	しない
;						FLG=xxxx1xxx
;						bit3=1	　する
;	　ドット表示指令	FLG=x000xxxx　表示なし
;						bit4=1	2,5桁点燈
;						bit5=1	3,6桁点燈
;						bit6=1	4,7桁点燈
;	　エラーフラグ		FLG=1xxxxxxx　エラー発生
;						FLG=0xxxxxxx　エラー無
;

;			上位桁から書き込みます
;
;		コードBフォントの使用方法
;		DBUFx　	各桁バッファ データフォーマット（Bモードに適用）
;		bit0-3	表示する十進数値データ	0H-9H→0-9(注1)
;				0AH→-、0BH→E、OCH→H、0DH→L、0EH→P
;				0FH=Blank(注2)
;		bit4	不使用
;		bit5	不使用
;		bit6	不使用
;		bit7　　ドット表示	0=OFF、1=ON
;		注1)表示数値データはMAX2719内部でLED表示ビットデータに変換されます
;		注2)ブランク命令はa-gセグメントのみ有効、DPセグメントには適応されない
;
;

SETBUF
;			表示する十進数値データを全バッファに書込み
			swapf	digit78,W
			andlw	0fh			;8桁目のみのデータを抽出
			movwf	DBUF7		;8桁目バッファに抽出データ書込み
								;以下同じ
			movf	digit78,W
			andlw	0fh
			movwf	DBUF6		;7桁目に数値データ書込み

			swapf	digit56,W
			andlw	0fh
			movwf	DBUF5		;6桁目に数値データ書込み

			movf	digit56,W
			andlw	0fh
			movwf	DBUF4		;5桁目に数値データ書込み

			swapf	digit34,W
			andlw	0fh
			movwf	DBUF3		;4桁目に数値データ書込み

			movf	digit34,W
			andlw	0fh
			movwf	DBUF2		;3桁目に数値データ書込み

			swapf	digit12,W
			andlw	0fh
			movwf	DBUF1		;2桁目に数値データ書込み

			movf	digit12,W
			andlw	0fh
			movwf	DBUF0		;1桁目に数値データ書込み

;			その他指定処理を全バッファに行う
;			呼び出し順番によっては上手く機能しなくなるので注意
			call	ZBK			;ゼロブランキング処理
			call	SPOS		;指定表示桁数処理
			call	ADDOT		;ドット表示処理

;			オーバーフローチェック
;			警告LEDを発光させる、7セグ表示は残り8桁分を表示
			movf	digit9A,W	;ここにデータがある場合O.Fとなる
			iorlw	0h
			btfss	STATUS,Z
			goto	sbfer
;			bcf		PORTA,5
			retlw	0h
sbfer
;			bsf		PORTA,5		;オーバーフロー発生
			retlw	01h

;
;			ゼロブランキング処理
;
;		入力		DBUFx　（数値データ設定済であること)
;					FLG	ビット3　ZBKフラグ
;		使用ワーク	無
;
;		方法		数値データ=0FHとする(CMD0)（注1）
;					その場合、DPセグメントは処理されない
;
;
;		注1）	表示桁数とゼロブランキングについて
;				ゼロブランキング処理にスキャンレジスタ使用はNG
;
;
ZBK
			btfss	FLG,3		;ZBK命令フラグチェック
			return				;命令無いので終了
			movf	DBUF7,W		;
			andlw	0fh			;数値データゼロチェック
			btfss	STATUS,Z
			return				;データはゼロで無いので終了
			movlw	0fh
			movwf	DBUF7		;ブランキングセット

			movf	DBUF6,W		;
			andlw	0fh			;数値データゼロチェック
			btfss	STATUS,Z
			return				;データはゼロで無いので終了
			movlw	0fh
			movwf	DBUF6		;ブランキングセット

			movf	DBUF5,W		;
			andlw	0fh			;数値データゼロチェック
			btfss	STATUS,Z
			return				;データはゼロで無いので終了
			movlw	0fh
			movwf	DBUF5		;ブランキングセット

			movf	DBUF4,W		;
			andlw	0fh			;数値データゼロチェック
			btfss	STATUS,Z
			return				;データはゼロで無いので終了
			movlw	0fh
			movwf	DBUF4		;ブランキングセット

			movf	DBUF3,W		;
			andlw	0fh			;数値データゼロチェック
			btfss	STATUS,Z
			return				;データはゼロで無いので終了
			movlw	0fh
			movwf	DBUF3		;ブランキングセット

			movf	DBUF2,W		;
			andlw	0fh			;数値データゼロチェック
			btfss	STATUS,Z
			return				;データはゼロで無いので終了
			movlw	0fh
			movwf	DBUF2		;ブランキングセット

			movf	DBUF1,W		;
			andlw	0fh			;数値データゼロチェック
			btfss	STATUS,Z
			return				;データはゼロで無いので終了
			movlw	0fh
			movwf	DBUF1		;ブランキングセット

			return				;DBUF0はゼロブランキングしない


;
;			表示桁位置調整サブルーチン
;			データバッファへの準備ルーチンから呼ばれる事を想定
;
;			指定表示桁数になるまでバッファのデータを右シフトする
;			余った左側桁は「0」に書換える
;			はみ出た下位桁は破棄される
;
;		入力		DBUFx   調整処理するデータバッファ
;					colum   設定表示桁数（ここでFLGから設定される）
;		出力        DBUFx   調整処理されたデータバッファ
;		使用ワーク	
;					colw0   桁位置ワーク
;

SPOS
			movf	FLG,W
			andlw	0fh			;設定桁数
			movwf	colum
			movlw	07h
			subwf	colum,W		;バイトシフト回数設定
			btfsc	STATUS,C	;ボローなら処理開始
			return				;表示桁変更無で終了
			movf	colum,W		;バイトシフト回数設定
			sublw	07h			;W=07-W
			movwf	colw0
spos01		;1バイト右シフト
			movf	DBUF1,W		;DB1→DB0
			movwf	DBUF0

			movf	DBUF2,W		;DB2→DB1
			movwf	DBUF1

			movf	DBUF3,W		;DB3→DB2
			movwf	DBUF2

			movf	DBUF4,W		;DB4→DB3
			movwf	DBUF3

			movf	DBUF5,W		;DB5→DB4
			movwf	DBUF4

			movf	DBUF6,W		;DB6→DB5
			movwf	DBUF5

			movf	DBUF7,W		;DB7→DB6
			movwf	DBUF6

			movlw	0fh			;
			movwf	DBUF7		;ブランクセット

			decf	colw0,F
			btfss	STATUS,Z
			goto	spos01
			retlw	0h


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
;			ドットを表示するか否かの処理ルーチン
;
;		入力	FLG
;
;		出力	DBUFx,7=0		ドット点燈無
;		出力	DBUFx,7=1		ドット点燈有
;
;		FLG
;			ドット表示位置		flg=x111xxxx
;							bit4=1	2,5桁点燈
;							bit5=1	3,6桁点燈
;							bit6=1	4,7桁点燈
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

ADDOT
			bcf		DBUF0,7		;ドット点灯ビットリセット
			bcf		DBUF1,7		;
			bcf		DBUF2,7		;
			bcf		DBUF3,7		;
			bcf		DBUF4,7		;
			bcf		DBUF5,7		;
			bcf		DBUF6,7		;
			bcf		DBUF7,7		;

			;2,5桁点燈指令チェック
			btfss	FLG,4		;2,5点燈指令か？
			goto	adt2		;違うので次ビットチェック
			;2桁目点燈処理
			movf	DBUF1,W
			call	ckbrk
			iorlw	0h
			btfsc	STATUS,Z
			bsf		DBUF1,7		;2桁目ドット点燈
			;5桁目点燈処理
			movf	DBUF4,W
			call	ckbrk
			iorlw	0h
			btfsc	STATUS,Z
			bsf		DBUF4,7		;5桁目ドット点燈
			return

adt2		;3,6桁点燈指令チェック
			btfss	FLG,5		;3,6点燈指令か？
			goto	adt4		;違うので次ビットチェック
			;3桁目点燈処理
			movf	DBUF2,W
			call	ckbrk
			iorlw	0h
			btfsc	STATUS,Z
			bsf		DBUF2,7		;3桁目ドット点燈
			;6桁目点燈処理
			movf	DBUF5,W
			call	ckbrk
			iorlw	0h
			btfsc	STATUS,Z
			bsf		DBUF5,7		;6桁目ドット点燈
			return

adt4		;4,7桁点燈指令チェック
			btfss	FLG,6		;4,7点燈指令か？
			return				;点灯無終了
			;4桁点燈処理
			movf	DBUF3,W
			call	ckbrk
			iorlw	0h
			btfsc	STATUS,Z
			bsf		DBUF3,7		;4桁目ドット点燈
			;7桁目点燈処理
			movf	DBUF6,W
			call	ckbrk
			iorlw	0h
			btfsc	STATUS,Z
			bsf		DBUF6,7		;7桁目ドット点燈
			return


;
;		ブランキング処理済みかどうかチェック
;
;		入力	WregにDBUFxのデータ
;		出力	W=0、表示有効データあり
;				W=1、ブランク処理済み桁
;

ckbrk		;
			andlw	0fh
			movwf	tmp0
			incf	tmp0,F
			btfss	tmp0,4
			retlw	0h
			retlw	01h

;
;		8桁すべて表示させる
;		表示位置指定はできない
;		表示データは、バッファレジスタDBUFxに事前に準備必要
;
;		入力		DBUF0-DBUF7
;
;		番号は桁番号と一致、例)DBUF7=8桁目（最上位桁）
;
;	Bモード（デコード有）アドレッシング
;		上位	下位（D15-D0の16ビット)
;		x0H	xxH		NOP
;		x1H	00H-07H	0桁0-9表示（ドット無）
;		x1H	80H-87H	0桁0-9表示（ドット有）
;		x1H	*0H-*7H	*bit7=1でドット有、bit4-6は何でもいい
;		x1H	F0H-F7H	0桁0-9表示（ドット有）
;
;		x2H	**H-**H	1桁、下位7ビットは上記と同じ
;		x3H	**H-**H	2桁、下位7ビットは上記と同じ
;		x4H	**H-**H	4桁、下位7ビットは上記と同じ
;		x5H	**H-**H	5桁、下位7ビットは上記と同じ
;		x6H	**H-**H	6桁、下位7ビットは上記と同じ
;		x7H	**H-**H	7桁、下位7ビットは上記と同じ
;		x8H	**H-**H	8桁、下位7ビットは上記と同じ
;


PUTL
			movf	DBUF0,W		;桁データをレジスタに転送
			movwf	CMD0
			movlw	01h
			movwf	CMD1
			call	SEND_CMD

			movf	DBUF1,W
			movwf	CMD0
			incf	CMD1,F
			call	SEND_CMD

			movf	DBUF2,W
			movwf	CMD0
			incf	CMD1,F
			call	SEND_CMD

			movf	DBUF3,W
			movwf	CMD0
			incf	CMD1,F
			call	SEND_CMD

			movf	DBUF4,W
			movwf	CMD0
			incf	CMD1,F
			call	SEND_CMD

			movf	DBUF5,W
			movwf	CMD0
			incf	CMD1,F
			call	SEND_CMD

			movf	DBUF6,W
			movwf	CMD0
			incf	CMD1,F
			call	SEND_CMD

			movf	DBUF7,W
			movwf	CMD0
			incf	CMD1,F
			call	SEND_CMD

			return



;
;		8桁すべてブランク表示とする
;
BRKL
			movlw	0fh			;ブランクコマンド
			movwf	CMD0
			movlw	01h
			movwf	CMD1
			call	SEND_CMD
			incf	CMD1,F
			call	SEND_CMD
			incf	CMD1,F
			call	SEND_CMD
			incf	CMD1,F
			call	SEND_CMD
			incf	CMD1,F
			call	SEND_CMD
			incf	CMD1,F
			call	SEND_CMD
			incf	CMD1,F
			call	SEND_CMD
			incf	CMD1,F
			call	SEND_CMD
			return


;
;		MAX2719　コマンドパケット送出サブルーチン
;
;		事前にCMD0、CMD1に命令コードを入れておくこと
;		CMDxのデータは保存される
;
;		RC3=DATA(DIN)
;		RC4=LATCH(LOAD)
;		RC5=CLOCK(CLK)
;
;		パケット送出シークェンス（１コマンドパケットは１６ビット幅)
;		(1)CLK=0、LOAD=0
;		(2)DINにデータビットをセット（bit15からbit0へ順番にセット)
;		(3)CLK=L→HでDINのデータビットはシフトレジスタにロードされる
;		(4)CLK=H→Lにして、(2)に行く、これを16回繰り返す
;		(5)LOAD=L→Hで16bitのシフトレジスタ内容がラッチされる
;		(6)CLK=0、LOAD=0にして終了
;
;		使用ワーク
;			CMD0	命令コード下位8ビット
;			CMD1	命令コード上位8ビット
;			tmp0	カウントワーク
;			tmp1	コマンドワーク

SEND_CMD
			bcf		PORTC,5		;CLK=0
			nop
			bcf		PORTC,4		;LOAD=0
			movf	CMD1,W
			movwf	tmp1		;上位8ビット送出データ
			call	sendbt
			movf	CMD0,W
			movwf	tmp1		;下位8ビット送出データ
			call	sendbt

;			ラッチパルス送出して終了
			bsf		PORTC,4		;LOAD=1
			call	w01u
			bcf		PORTC,4		;LOAD=0
			call	w01u
			return

sendbt		;シフトレジスタに8ビット分送出、ラッチはしない
			movlw	08h			;8ビット分
			movwf	tmp0		;カウンタ
sbtlp		lslf	tmp1,F		;C=MSB
			btfsc	STATUS,C
			goto	sbt01

sbt00		;DATA=0送出
			bcf		PORTC,3		;DIN=0
			call	w01u		;ウエイト1us
			bsf		PORTC,5		;CLK=1
			call	w01u		;ウエイト1us
			bcf		PORTC,5		;CLK=0
			goto	sbten

sbt01		;DATA=1送出
			bsf		PORTC,3		;DIN=1
			call	w01u		;ウエイト1us
			bsf		PORTC,5		;CLK=1
			call	w01u		;ウエイト1us
			bcf		PORTC,5		;CLK=0

sbten		;
			decfsz	tmp0,F
			goto	sbtlp		;残ビットチェック
			call	w01u		;ウエイト1us
			return


;
;		Wregの8ビットデータを送信し、ラッチはしない
;
;		これによりMAX2719シフトレジスタの上位8ビットに転送される
;		それまでの上位8ビットデータは下位8ビットにシフトする。
;		旧下位8ビットデータはDOUTから破棄されます。
;		MAX2719は何の反応もしない
;
;		RC3=DATA(DIN)
;		RC4=LATCH(LOAD)
;		RC5=CLOCK(CLK)
;
;		使用変数	wrk0、wrk1
;

PUTW
			movwf	wrk0		;送信8ビットデータ
			movlw	08h			;8ビット分送出カウンタ
			movwf	wrk1		;カウンタ
			bcf		PORTC,5		;CLK=0
			nop
			bcf		PORTC,4		;LOAD=0
ptwlp
			lslf	wrk0,F		;C=LSB
			btfsc	STATUS,C
			goto	ptw01

ptw00		;DATA=0送出
			bcf		PORTC,3		;DIN=0
			call	w01u		;ウエイト1usec
			bsf		PORTC,5		;CLK=1
			call	w01u		;ウエイト1usec
			bcf		PORTC,5		;CLK=0
			goto	ptwen

ptw01		;DATA=1送出
			bsf		PORTC,3		;DIN=1
			call	w01u		;ウエイト1usec
			bsf		PORTC,5		;CLK=1
			call	w01u		;ウエイト1usec
			bcf		PORTC,5		;CLK=0

ptwen		;
			decfsz	wrk1,F
			goto	ptwlp		;残ビット有
			return


;			ラッチパルス送出
;
;			コールするだけでOK
;
PTLAT		bsf		PORTC,4		;LOAD=1
			call	w01u
			bcf		PORTC,4		;LOAD=0
			call	w01u
			return


;
;			32ビットバイナリ10倍演算(符号無整数)
;
;		入力	hex(0-3)	32ビット
;		出力	hex(0-3)
;
;		使用ワーク	hexw0-3	4バイト
;

MLT32_X10
;			データ保存
			movf	hex0,W
			movwf	hexw0
			movf	hex1,W
			movwf	hexw1
			movf	hex2,W
			movwf	hexw2
			movf	hex3,W
			movwf	hexw3

;			32ビットデータを8倍
			bcf		STATUS,C	;
			rlf		hex0,F		;2倍を3回実行する
			rlf		hex1,F
			rlf		hex2,F
			rlf		hex3,F
			bcf		STATUS,C	;
			rlf		hex0,F
			rlf		hex1,F
			rlf		hex2,F
			rlf		hex3,F
			bcf		STATUS,C
			rlf		hex0,F
			rlf		hex1,F
			rlf		hex2,F
			rlf		hex3,F

			call	ADD32B		;元データを加算
			call	ADD32B


			btfss	STATUS,C	;オーバーフローか？
			retlw   0h
            retlw   01h

;
;       16ビットバイナリ　4倍演算（符号無整数)
;
;       hex0,hex1=(hex0,hex1)*2
;		W=0の時、正常終了
;		W=1の時、エラー発生、演算結果は保障されない
;
MLT16_X4
            bcf     STATUS,C    ;Cフラグクリア
            rlf     hex0,F      ;左ローテート（下位8ビット×２）
            rlf     hex1,F      ;左ローテート（上位8ビット×２）
            btfsc   STATUS,C
            retlw   01h         ;演算オーバーフロー発生
            rlf     hex0,F      ;左ローテート（下位8ビット×２）
            rlf     hex1,F      ;左ローテート（上位8ビット×２）
            btfss   STATUS,C
            retlw   0h          ;演算正常終了
            retlw   01h         ;演算オーバーフロー発生


;			32ビットバイナリ加算(整数符号無）
;
;		事前に(hex0-3)、(hexw0-3)に数値を入れておく事
;		演算結果でエラー(桁上がり）が発生しても対処はしない
;
;		演算
;		hex(0-3) = hex(0-3) + hexw(0-3)
;

ADD32B
			movf	hexw0,W		;hex0=hex0+hexw0
			addwf	hex0,F		;桁上がりでC=1
			movlw	01h			;この命令はフラグ変化しない
			btfss	STATUS,C	;if c=1 then hex1=hex1+1
			goto	ad31		;桁上がり無
;			(hex0+W)に桁上がり発生、処理
			addwf	hex1,F		;hex1=hex1+1
			btfsc	STATUS,C	;桁上がり無なら、goto ad31
			addwf	hex2,F		;桁上がり発生、hex2=hex2+1
			btfsc	STATUS,C	;桁上がり無なら、goto ad31
			addwf	hex3,F		;桁上がり発生、hex3=hex3+1
								;ここで桁上がり発生しても対処しない
ad31		movf	hexw1,W
			addwf	hex1,F
			movlw	01h
			btfsc	STATUS,C
			addwf	hex2,F
			btfsc	STATUS,C
			addwf	hex3,F

ad32		movf	hexw2,W
			addwf	hex2,F
			movlw	01h
			btfsc	STATUS,C
			addwf	hex3,F
			movf	hexw3,W
			addwf	hex3,F
			retlw	0h


;
;
;			32ビットバイナリ減算(整数符号無)
;
;		事前にhex(0-3)、hexw(0-3)に数値を入れておく事
;		演算結果でエラー(マイナス）の場合W=1、OKの時はW=0でリターン
;		W=1の場合、演算結果は保障されない
;
;		演算
;		hex(0-3) = hex(0-3) - hexw(0-3)
;

SUB32B
;			hex0-hexw0の減算
			movf	hexw0,W		;hex0=hex0-W(hexw0)
			subwf	hex0,F		;W>HEX0の時、ボロー(C=0)
								;W<=HEX0の時、無(C=1)
			movlw	01h			;この命令はフラグ変化しない
			btfss	STATUS,C	;C=1なら、hex1-hexw1へ
;			(hex0-W)にボロー発生、hex1に桁借り処理
			subwf	hex1,F		;hex1=hex1-1
			btfss	STATUS,C	;C=1なら、goto sb31
			subwf	hex2,F		;(hex1-1)にボロー発生、hex2に桁借り
			btfss	STATUS,C	;C=1なら、goto sb31
			subwf	hex3,F		;(hex2-1）ボロー発生、hex3に桁借り
			btfss	STATUS,C
			retlw	01h			;hex3にボロー発生、エラー終了

;			hex1-hexw1の減算
sb31		movf	hexw1,W		;
			subwf	hex1,F
			movlw	01h
			btfss	STATUS,C
			subwf	hex2,F
			btfss	STATUS,C
			subwf	hex3,F
			btfss	STATUS,C
			retlw	01h
;			hex2-hexw2の減算
			movf	hexw2,W
			subwf	hex2,F
			movlw	01h
			btfss	STATUS,C
			subwf	hex3,F
			btfss	STATUS,C
			retlw	01h
;			hex3-hexw3の減算
			movf	hexw3,W
			subwf	hex3,F
			btfss	STATUS,C
			retlw	01h
			retlw	0h

;		16ビットバイナリ加算
;		hex(0-1)=hex(0-1)+hexw(0-1)
;		W=0の時、正常終了
;		W=1の時、エラー発生（キャリー）、演算結果は保障されない
ADD16B
			movf	hexw0,W		;W=hexw0
			addwf	hex0,F		;hex0=hex0+hexw0
			btfss	STATUS,C
			goto	ad11		;キャリー無で次の加算
			incf	hex1,F		;キャリー発生、hex1=hex1+1
			btfsc	STATUS,C
			retlw	01h			;キャリー発生、加算エラー終了
ad11		movf	hexw1,W		;W=hexw1
			addwf	hex1,F		;hex1=hex1+hexw1
			btfsc	STATUS,C
			retlw	01h			;キャリー発生、加算エラー終了
			retlw	0h			;加算正常終了


;		16ビットバイナリ減算
;		hex(0-1)=hex(0-1)-hexw(0-1)
;		W=0の時、正常終了
;		W=1の時、エラー発生（ボロー）、演算結果は保障されない
SUB16B
			movf	hexw0,W		;W=hexw0
			subwf	hex0,F		;hex0=hex0-hexw0
			movlw	01h			;フラグ変化しない
			btfsc	STATUS,C
			goto	sb11		;ボロー無で次の減算
			subwf	hex1,F		;ボロー発生、hex1=hex1-1
			btfss	STATUS,C
			retlw	01h			;ボロー発生、減算エラー終了

sb11		movf	hexw1,W		;W=hexw1
			subwf	hex1,F		;hex1=hex1-hexw1
			btfss	STATUS,C
			retlw	01h			;ボロー発生、減算エラー終了
			retlw	0h			;減算正常終了


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
;		４バイトバイナリの10桁BCDへの変換
;		MicroChip社のアプリケーションノートより
;
;		入力		4バイト(32ビット)16進バイナリ
;				hex0
;				hex1
;				hex2
;				hex3
;
;		出力		5バイト(10桁)ＢＣＤ
;				digit12
;				digit34
;				digit56
;				gidit78
;				gidit9A
;
;		使用ワーク
;				hexw0	入力データ保存用
;				hexw1
;				hexw2
;				hexw3
;				shift	シフトカウンタ
;				bcdw0	補正処理ワーク
;				bcdw1
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
BCD
			BCF		STATUS,C	;キャリーリセット
			MOVLW	020H		;シフトカウンタ初期化
			MOVWF	shift		;4バイト分32回の指定
			CLRF	digit12		;BCDデータエリア初期化
			CLRF	digit34
			CLRF	digit56
			CLRF	digit78
			CLRF	digit9A
			movf	hex0,W
			movwf	hexw0
			movf	hex1,W
			movwf	hexw1
			movf	hex2,W
			movwf	hexw2
			movf	hex3,W
			movwf	hexw3

			;変換ループ処理
loop
			RLF		hexw0,F		;16進データ左シフト
			RLF		hexw1,F
			RLF		hexw2,F
			RLF		hexw3,F
			RLF		digit12,F	;BCDデータ左シフト
			RLF		digit34,F
			RLF		digit56,F
			RLF		digit78,F
			RLF		digit9A,F
			DECFSZ	shift,F		;
			GOTO	adjst		;BCD調整処理へ
			RETURN

			;BCDデータ全桁補正処理
adjst
			MOVF	digit12,W	;digit12
			CALL	adjbcd
			MOVWF	digit12
			MOVF	digit34,W	;digit34
			CALL	adjbcd
			MOVWF	digit34
			MOVF	digit56,W	;digit56
			CALL	adjbcd
			MOVWF	digit56
			MOVF	digit78,W	;digit78
			CALL	adjbcd
			MOVWF	digit78
			MOVF	digit9A,W	;digit9A
			CALL	adjbcd
			MOVWF	digit9A
			GOTO	loop

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
;			1バイト2桁分必要に応じて+3補正処理
;
;			入力		W_reg
;			出力		W_reg
;
;			使用ワーク	bcdw0
;					bcdw1
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
adjbcd
			MOVWF	bcdw0		;元データをbcdw0に保存
			MOVLW	3			;W=3
			ADDWF	bcdw0,W		;W=3+bcdw0
			MOVWF	bcdw1		;下桁を+3した上下桁をbcdw1に保存
			BTFSC	bcdw1,3		;if 下桁<7 then next_skip
			MOVWF	bcdw0		;下桁を+3した上下桁をbcdw0に保存

			MOVLW	030H		;W+30
			ADDWF	bcdw0,W		;W=上桁+3
			MOVWF	bcdw1		;それをいったんbcdw1に保存
			BTFSC	bcdw1,7		;if 上桁<7 then next_skip
			MOVWF	bcdw0		;上桁を+3した上下桁をbcdw0に保存
			MOVF	bcdw0,W		;W_regに入れてリターン
			RETURN


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
;			遅延時間サブルーチン	32MHZ用
;
;		1cycle	= 0.125us
;		使用レジスタ	= cnt2,cnt3
;		BSR		=0(BANK0)
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

wait100u						;呼び出しも含めて、100us
								;call is 2cycles
			movlw	09h			;1
			movwf	cnt2		;1
			movlb	0h
			nop
			nop					;3
w100u		nop					;
			call	w10u		;10*9=90us(ここだけ命令ステップを数えない）
			decfsz	cnt2,F		;4*8+3=31cycles
			goto	w100u
			return				;2+5+31+2=40cycles=20us

wait50u							;呼び出しも含めて、50us
			call	wait25u
wait25u							;呼び出しも含めて、25us
			call	w10u
			call	w10u
			movlw	0bh			;5us=0.125us*40cycles
			movwf	cnt2		;
w25u		decfsz	cnt2,F		;ループ 2+10*3+2=34cycles
			goto	w25u
			nop
			nop
			return				;2+34+2+2=40cycles=5us

wait5m							; 5ms
			movlb	0h
			movlw	05h
			movwf	cnt2
w5m			call	w1m
			decfsz	cnt2,F
			goto	w5m
			return

wait10m							; 10ms
			movlb	0h
			movlw	d'10'
			movwf	cnt2
w10m		call	w1m
			decfsz	cnt2,F
			goto	w10m
			return

wait20m							; 20ms
			movlb	0h
			movlw	d'20'
			movwf	cnt2
w20m		call	w1m
			decfsz	cnt2,F
			goto	w20m
			return
wait50m							; 50ms
			movlb	0h
			movlw	d'50'
			movwf	cnt2
w50m		call	w1m
			decfsz	cnt2,F
			goto	w50m
			return

wait100m						; 100ms
			movlb	0h
			movlw	d'100'
			movwf	cnt2
w100m		call	w1m
			decfsz	cnt2,F
			goto	w100m
			return

wait500m						; 500ms
			movlb	0h
			movlw	05h
			movwf	cnt3
w500m		call	wait100m
			decfsz	cnt3,F
			goto	w500m
			return

wait1s							; 1s
			movlb	0h
			movlw	d'10'
			movwf	cnt3
w1s			call	wait100m
			decfsz	cnt3,F
			goto	w1s
			return

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
;			1ms 基本ウェイト
;			呼び出しを含めて1msとなる。
;
;		clock	= 32MHz(0.03125usec)
;		1cycle	= 0.125usec
;		1ms		= 0.125usec * 8000cycles
;
;			使用変数　cnt0,cnt1
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
w1m
			movlb	0h
			movlw	08h
			movwf	cnt0		;
;			外周ループ
w1m0		movlw	0c7h		;199d
			movwf	cnt1		;
;			内周ループ
w1m1		nop					;
			nop					;5cycles*cnt1
			decfsz	cnt1,F		;2+5*198+4=996c/s
			goto	w1m1		;
;
			decfsz	cnt0,F		;
			goto	w1m0		;2+7*999+998=7993cycles
			nop
			return					;other=(3+4)cycles
									;Total 8000*0.125us=1ms


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
;			10us 基本ウェイト
;			呼び出し（call　w10u)も含めて、10usとなる。
;
;		clock	= 32MHZ(0.03125us)
;		1cycle	= 0.125us
;		10us	= 0.125us * 80cycles
;		使用変数　cnt0,cnt1
;		'goto','call','return'は2サイクル消費する
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

w10u
			movlb	0h
			movlw	018h		;18H=24
			movwf	cnt0		;
w10u0		decfsz	cnt0,F		;3*23+2=71
			goto	w10u0		;
			nop
			nop
			return				;2+3+71+2+2=80cycles

w05u
			movlw	0bh			;5us=0.125us*40cycles
			movwf	cnt0		;
w05u0		decfsz	cnt0,F		;ループ 2+3*10+2=34cycles
			goto	w05u0
			nop
			nop
			return				;2+34+2+2=40cycles=5us

w02u
			movlw	04h			;2us=0.125us*16cycles
			movwf	cnt0		;
w02u0		decfsz	cnt0,F		;2+3*3+2+1+2=16cycles
			goto	w02u0
			nop
			return				;
w01u
			nop					;1us=0.125us*8cycles
			nop					;2+4+2=8cycles
			nop
			nop
			return

;

;
            END

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
;			遅延時間サブルーチン
;
;		clock	= 8MHz(0.125us)
;		1cycle	= 0.5us
;		使用レジスタ	= cnt0,cnt1,cnt2,cnt3
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

wait100u						;呼び出しも含めて、100us
								;call is 2cycles
			movlw	09h			;1
			movwf	cnt2		;1
			nop
			nop
			nop					;3
w1u			nop					;
			call	d10u		;10*8=80us(ここだけ命令ステップを数えない）
			decfsz	cnt2,F		;4*7+3=31cycles
			goto	w1u
			return				;2+5+31+2=40cycles=20us

wait50u							;呼び出しも含めて、50us
			call	wait25u
wait25u							;呼び出しも含めて、25us
			call	d10u
			call	d10u
			nop					;5us=0.5us*10cycles			
			nop					;
			nop
			nop
			nop
			nop
			return				;2+6+2=10cycles=5us

wait2m
			movlw	02h
			movwf	cnt2
w2m			call	d1m
			decfsz	cnt2,F
			goto	w2m
			return

wait5m							; 5ms delay
			movlw	05h
			movwf	cnt2
w5m			call	d1m
			decfsz	cnt2,F
			goto	w5m
			return

wait10m							; 10ms delay
			movlw	d'10'
			movwf	cnt2
w10m		call	d1m
			decfsz	cnt2,F
			goto	w10m
			return

wait20m							; 20ms delay
			movlw	d'20'
			movwf	cnt2
w20m		call	d1m
			decfsz	cnt2,F
			goto	w20m
			return
wait50m							; 50ms delay
			movlw	d'50'
			movwf	cnt2
w50m		call	d1m
			decfsz	cnt2,F
			goto	w50m
			return

wait100m						; 100ms delay
			movlw	d'100'
			movwf	cnt2
w100m		call	d1m
			decfsz	cnt2,F
			goto	w100m
			return

wait500m						; 500ms delay
			movlw	05h
			movwf	cnt3
w500m		call	wait100m
			decfsz	cnt3,F
			goto	w500m
			return

wait1s							; 1s delay
			movlw	d'10'
			movwf	cnt3
w1s			call	wait100m
			decfsz	cnt3,F
			goto	w1s
			return

;			Wregで指定した回数10msウェイトルーチンを呼び出す
waitx
			movwf	work1		;
wtx			call	wait10m
			decfsz	work1
			goto	wtx
			return

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
;			1ms 基本ウェイト 
;
;		clock	= 8MHz(0.125usec)
;		1cycle	= 0.5usec
;		1ms		= 0.5usec * 2000cycles
;
;		# 'goto' and 'call' and 'return' - 2cycles
;			使用変数　cnt0,cnt1
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
d1m
			movlw		02h
			movwf		cnt0		;
;			外周ループ
d1m0		movlw		0c7h		;199d
			movwf		cnt1		;
;			内周ループ
d1m1		nop						;
			nop						;5cycles*cnt1
			decfsz		cnt1,F		;5*199=995c/s
			goto		d1m1		;
;
			decfsz		cnt0,F		;(d1m1-1+3)*cnt0
			goto		d1m0		;(995-1+5)*2=1998cycles
			return					;other=3cycles
									;Total 2001*0.5usec=約1ms

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
;			10us 基本ウェイト
;			呼び出しも含めて、10usとなる。
;
;		clock	= 8MHZ(0.125us)
;		1cycle	= 0.5us
;		10us	= 0.5us * 20cycles
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

									;"call" inst = 2cycles
d10u
			movlw		05h			;1
			movwf		cnt0		;1
d10u0								;3*4+2=14
			decfsz		cnt0,F		;
			goto		d10u0		;
			return					;2+1+1+14+2=20cycles
