 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
;		ＰＩＣ１６Ｆ１８２８　Ｉ２Ｃ-パラレル変換
;
;							2016年7月	Ver1.0	JA0QON
;
;		パラレル接続ＬＣＤをＩ２Ｃ接続で使う実験
;
;
;	ターゲットディスプレイ
;		SC1602 パラレル接続16桁2行液晶モジュール
;
;		PIC16F1828 32MHZ 内部発振
;		データバスは8bit
;		受信コマンドのチェックはしていない
;		コマンドワード間ウエイトも考慮されていない
;		マスタへの送信は未対応
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

		LIST	P=PIC16F1828
		INCLUDE	P16F1828.INC

;
;CONFIGURATION WORD 1(ADDRESS:8007H)
;					設定
;bit13		FCMEN	0	Fail-Safe Clock Monitor
;						1=有効,0=無効
;bit12		IESO	0	内部･外部切替スイッチモード
;			________	1=有効,0=無効
;bit11		CLKOUTEN 1	クロック出力イネーブルビット
;						1=無効　RA4I/O使用可
;						0=有効　クロックがCLKPUTピンに出力される
;bit10-9	BOREN	00	ブラウンアウト設定
;						11=有効
;						10=スリープ時以外有効
;			___			00=無効
;bit8		CPD		1	データメモリプロテクション
;			__			1=無効,0=有効
;bit7		CP		1	プログラムメモリプロテクション　
;						1=無効,0=有効
;bit6		MCLRE	0	RA3/MCLRピン選択ビット
;			_____		1=MCLR有効,0=RA3有効(Digital input)
;bit5		PWRTE	0	power_up timer　使います。
;						1=無効,0=有効
;bit4-3		WDTE	00	Watchdog Timer
;						11=有効
;						10=ランニング中に有効、スリープ中は無効
;						01=レジスタによるコントロール
;						00=無効
;bit2-0		FOSC	100	発振器選択ビット
;						111=ECH:外部クロック入力（4-32MHZ)、RA4I/O可
;						110=ECM:外部クロック入力（0.5-4MHZ)、RA4I/O可
;						101=ECL:外部クロック入力（0-0.5MHZ)、RA4I/O可
;						100=INTOSC:内部発振、RA4-RA5I/O可
;						011=EXTRC:外部RC発振、RA4I/O可、RA5不可
;						010=HS：外部発振子、I/O不可
;						001=XT：　〃
;						000=LP：　〃
;
;bit	15 14 13 12 11 10 09 08 07 06 05 04 03 02 01 00
;data    0  0  0  0  1  0  0  1  1  0  0  0  0  1  0  0
;
;
	__CONFIG _CONFIG1,	B'0000100110000100'
;
;CONFIGURATION WORD 2(ADDRESS:8008H)マニュアル52ページ
;					設定
;bit13		LVP		0	低電圧プログラミング設定
;						1=有効
;			_____		0=無効、高電圧必要
;bit12		DEBUG	1	インサーキット･デバッガ モード設定
;						1=無効
;						0=有効、RA0-1をデバッガに使用
;bit11					Unimplemented(read = 1)
;bit10		BORV	0	ブラウンアウト･リセット電圧選択ビット（Vbor参照)
;						1=低電圧で動作
;						0=高電圧で動作
;bit9		STVREN	0	スタック･オーバーフロー･リセット設定
;						1=有効
;						0=無効
;bit8		PLLEN	0	PLL設定
;						1=4xPLL有効
;						0=4xPLL無効
;bit7-5					Unimplemented(read = 1)
;bit4					Reserved (read = 1)
;bit3-2					Unimplemented(read = 1)
;bit1-0		WRT		11	フラッシュメモリ プロテクション設定（EECONレジスタ参照)
;						11=無効
;						10=0h-1FFh有効
;						01=0h-3FFh有効
;						00=0h-7FFh有効
;
;bit	15 14 13 12 11 10 09 08 07 06 05 04 03 02 01 00
;data    0  0  0  1  1  0  0  0  1  1  1  1  1  1  1  1
;
;
	__CONFIG _CONFIG2,	B'0001100011111111'



;		ワークエリア定義
;
;		BANK0	20h-7Fh
;
;		使用していないのもあります
;

;演算引数・戻り値用
hex0		equ		020h		;32ビットバイナリ演算用
hex1		equ		021h		;
hex2		equ		022h
hex3		equ		023h
hexw0		equ		024h		;32ビットバイナリ演算用
hexw1		equ		025h
hexw2		equ		026h
hexw3		equ		027h
;ウエイト用専用ワーク
cnt0		equ		028h		;時間待ちルーチン用専用ワーク
cnt1		equ		029h
cnt2		equ		02ah
cnt3		equ		02bh
;汎用ローカルワーク
tmp0		equ		02ch		;汎用ワーク、その場所限定
tmp1		equ		02dh		;移動した場合、破壊されること有
;機能専用広域ワーク
FLG			equ		02eh		;8桁7セグLED表示設定フラグ
MODE		equ		02fh		;実行モード設定フラグ
DSPM		equ		030h		;ディスプレイモード スイッチフラグ
;A/Dコンバータ用専用ワーク
ADM0		equ		031h		;ADC下位データ
ADM1		equ		032h		;ADC上位データ
ADM2		equ		033h		;ADC保存過去データ
;DDS用広域ワーク
FRQ0		equ		034h		;32ビットDDS周波数データ
FRQ1        equ     035h        ;
FRQ2		equ		036h		;
FRQ3		equ		037h		;
TBAL        equ     038h        ;参照テーブル先頭アドレス下位8ビット
TBAH        equ     039h        ;同上位8ビット
;BCD用広域ワーク
digit12     equ     03ah        ;BCD変換出力1，2桁
digit34     equ     03bh		;BCD変換出力3，4桁
digit56     equ     03ch        ;BCD変換出力5，6桁
digit78     equ     03dh        ;BCD変換出力7，8桁
digit9A     equ     03eh        ;BCD変換出力9，10桁
bcdw0		equ		03fh		;BCD補正処理ワーク
bcdw1		equ		040h
;汎用広域ワーク
wrk0		equ		041h        ;演算用汎用ワーク
wrk1		equ		042h
shift       equ     043h        ;ビットシフト用ワーク
blk			equ		044h		;ゼロブランキング制御フラグ
colum		equ		045h		;現在の桁位置
colw0		equ		046h		;桁位置処理ワーク
colw1		equ		047h		;
;8桁7セグLED専用広域ワーク
CMD0		equ		048h		;コマンドパケット下位8ビット
CMD1		equ		049h		;コマンドパケット上位8ビット
DBUF0		equ		04ah		;SPI送信データ編集用バッファ
DBUF1		equ		04bh
DBUF2		equ		04ch
DBUF3		equ		04dh
DBUF4		equ		04eh
DBUF5		equ		04fh
DBUF6		equ		050h
DBUF7		equ		051h
;ロータリーエンコーダ専用ワーク
REDAT       equ     052h        ;ロータリーエンコーダ・ビットデータ
RESP0       equ     053h        ;変化ステップ量 下位バイト
RESP1		equ		054h		;
RESP2		equ		055h		;
rew0        equ     056h        ;専用ワーク
rew1        equ     057h        ;専用ワーク
;メインループ用広域ワーク
FDA0        equ     058h		;32ビット アップダウン カウンタ
FDA1        equ     059h		;基本動作周波数用
FDA2		equ     05ah		;
FDA3		equ     05bh		;
FDB0		equ		05ch		;DDS用動作周波数
FDB1		equ		05dh		;
FDB2		equ		05eh		;
FDB3		equ		05fh		;
IFQ0		equ     060h		;中間周波数用差分データ
IFQ1		equ     061h		;
IFQ2		equ     062h		;
IFQ3		equ     063h		;
;
DSP_ADR     equ     064h
icw0        equ     065h
icw1        equ     066h
BFAD0		equ		067h		;バッファアドレス下位8bit
BFAD1		equ		068h		;バッファアドレス上位8bit
BFPT0		equ		069h		;バッファポインタ0
BFPT1		equ		06ah
MSAD0		equ		06bh
MSAD1		equ		06ch
LDWR		equ		06dh		;Wreg退避用
I2C_DATA	equ		06eh
CTRL		equ		06fh

;
;
;	ＦＩＦＯバッファ
;
;	A0H-BFH
;	FSR0でアクセス

;
			ORG		0h			;リセットベクタ
			goto	init
			ORG		04h			;割り込みベクタ

;
;		割込み処理ルーチン（ＭＳＳＰモジュールで発生)
;
;
;	割込み要件１	アドレスの受信および一致
;		I2Cアドレスが一致すると、マスタに／ＡＣＫを送信、
;		SSP1IFがセットされ、割り込み発生
;		SSP1IFがセットされているのを確認
;		SSP1BUFのデータを読み込む
;		SSP1IFをリセットする
;
;	割込み要件２	データバイトの受信
;		受信するとマスタに／ＡＣＫを送信
;		SSP1IFがセットされ、割り込み発生
;		SSP1IFを確認
;		SSP1BUFのデータを読み込む
;		SSP1IFをリセットする
;
;	割込み要件３	ＳＴＯＰの受信
;		SSP1IFがセットされ、割り込み発生
;		SSP1IFを確認
;		SSP1STATのPビットを確認
;		SSP1IFをリセットする
;		MSSPモジュールをディセーブルにする
;
;	ＬＥＤ制御
;		I2Cアドレス受信すると、LED(RB7)を点灯
;		ストップビットを検出すると、LEDを消灯
;
;	使用ワーク
;		I2C_DATA	受信したI2Cデータ(1バイト)を格納
;		MODE		I2C受信進行状況を示すフラグ
;					割込みルーチンでは、bit3-1を設定する
;					消去はここでは行わないので注意
;		bit7-6	予約
;		bit5	LCD_DATA
;		bit4	LCD_INST
;		bit3	I2C_STOP
;					1=I2Cストップビットを検出
;					0=コマンドワード受信継続中
;		bit2	I2C_DATA
;					1=I2Cデータバイトを受信
;					0=データは無効
;		bit1	I2C_ADRESS
;					1=I2Cスレーブアドレスを受信
;					0=受信待ち、あるいは現在データは無効
;		bit0	I2C_START（現在未使用）
;					1=I2Cスタートビットを検出
;					0=MSSP1はアイドル
;
INT
;	割込み要件の確認
			movlb	04h			;BANK4
;			btfsc	SSP1STAT,S	;現在割込み設定していない
;			goto	RCV_STA
			btfsc	SSP1STAT,P
			goto	RCV_STP
			btfsc	SSP1STAT,D_NOT_A
			goto	RCV_DATA
;	I2Cアドレスの受信
RCV_ADRS
			movlb	0h
			bcf		PIR1,SSP1IF	;割り込み原因クリア
			movlb	04h
			movf	SSP1BUF,W	;アドレスは破棄
			clrf	BSR
			bsf		MODE,1		;I2Cアドレス受信フラグ セット
			bcf		PORTB,7		;LED ON
			bra		INTOUT
;	I2Cデータの受信
RCV_DATA
			movlb	0h
			bcf		PIR1,SSP1IF	;割り込み原因クリア
			movlb	04h			;BANK4 SSP1関連
			movf	SSP1BUF,W	;受信データ取得
			clrf	BSR			;BANK0
			movwf	I2C_DATA
			bsf		MODE,2		;I2Cデータ受信フラグ セット
			bra		INTOUT
;	スタートビットの受信
RCV_STA
			clrf	BSR
			bsf		MODE,0		;START_BIT
			goto	INTOUT
;	ストップビットの受信
RCV_STP
			clrf	BSR
			bsf		MODE,3		;STOP_BIT
			bsf		PORTB,7		;LED OFF
;	割込み終了処理
INTOUT
			clrf	BSR
			bcf		PIR1,SSP1IF
			retfie				;

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
;			PIC16F1828　イニシャライズ
;
;		OSCCON(BANK1　099H)
;			bit7	SPLLEN	ソフトウエアPLL設定ビット
;							1 = 4xPLL有効
;							0 = 4xPLL無効(リセット後)
;			＊コンフィグレーションワードPLLEN=1の時、この設定は無視される。
;			bit6-3	IRCF	内部発振器クロック選択ビット
;							000x = 31KHZ LF
;							0010 = 31.25KHZ MF
;							0011 = 31.25KHZ HF
;							0100 = 62.5KHZ MF
;							0101 = 125KHZ MF
;							0110 = 250KHZ MF
;							0111 = 500KHZ MF（デフォルト）
;							1000 = 125kHZ HF
;							1001 = 250kHZ HF
;							1010 = 500kHZ HF
;							1011 = 1MHZ HF
;							1100 = 2MHZ HF
;							1101 = 4MHZ HF
;							1110 = 8MHZ or 32MHZ HF
;							1111 = 16MHZ HF
;			bit2			Unimplemented
;			bit1-0	SCS		システムクロック選択ビット
;							1x = 内部発振器
;							01 = タイマ1発振器
;							00 = FOSCで指定された発振器(リセット後)
;			(注)詳細はマニュアルあるいは当局HP内解説を参照
;							HF=HFINTOSC（16MHZ)
;							MF=MFINTOSC(500KHZ)
;							LF=LFINTOSC(32KHZ)
;
;
;			32MHZ内部発振設定
;		コンフィグレーションワード1		FOSC=100
;		OSCCON				SCS=00
;		OSCCON				IRCF=1110
;		OSCCON				SPLLEN=1(#1)
;		コンフィグレーションワード2		PLLEN=1(#1)
;						(#1)設定はどちらかでOKだが、PLLEN=1とすると、
;							OSCCONのSPLLEN=0の設定は無効となる。
;							また、8MHZのHFINTOSCは選択の余地が無い。
;
;		各ポートのデジタル入出力は、TTL入力、CMOS出力が基本
;		PORTA(BANK0　00CH）
;			bit7-6	Unimplemented(read=0)
;			bit5	RA5		デジタルI/O
;			bit4	RA4		デジタルI/O、アナログ入力
;			bit3	RA3		デジタルInputのみ(TTL)
;			bit2	RA2		デジタルI/O（CMOSシュミット）、アナログ入力
;			bit2	RA1		デジタルI/O、アナログ入力
;			bit0	RA0		デジタル･アナログI/O,DAコンバータ出力
;
;		PORTB(BANK0　00DH）
;			bit7-6	RB7-6	デジタルI/O
;			bit5-4	RB5-4	デジタルI/O、アナログ入力
;			bit3-0	Unimplemented(read=0)
;
;		PORTC(BANK0　00EH）
;			bit7-6	RC7-6	デジタルI/O、アナログ入力
;			bit5-4	RC5-4	デジタルI/O
;			bit3	RC3-0	デジタルI/O、アナログ入力
;
;		TRISA(BANK1　08CH)
;			bit7-6	Unimplemented(read=0)
;			bit5-4	RA5-4	1=入力、0=出力
;			bit3	RA3		常に1
;			bit2	RA2-0	1=入力、0=出力
;
;		TRISB(BANK1　08DH)
;			bit7-6	Unimplemented(read=0)
;			bit5-4	RB7-4	1=入力、0=出力
;
;		TRISC(BANK1　08EH)　マニュアル130ページ
;			bit7-6	Unimplemented(read=0)
;			bit5-4	RA5-0	1=入力、0=出力
;
;		LATA(BANK2　10CH)
;			bit7-6	Unimplemented(read=0)
;			bit5-4	RA5-4	出力データ保持
;			bit3	Unimplemented(read=0)
;			bit2	RA2-0	出力データ保持
;			（このラッチデータはTRISAレジスタ設定で各ピンに反映される）
;
;		LATB(BANK2　10DH)
;			bit7-4	RAB7-4	出力データ保持
;			bit3-0	Unimplemented(read=0)
;			（このラッチデータはTRISBレジスタ設定で各ピンに反映される）
;
;		LATC(BANK2　10EH)
;			bit7-6	Unimplemented(read=0)
;			bit5-0	RA5-4	出力データ保持
;			（このラッチデータはTRISCレジスタ設定で各ピンに反映される）
;
;
;		ANSELA(BANK3　18CH)
;			bit7-5	Unimplemented(read=0)
;			bit4	ANSA3/RA4	アナログ/デジタル選択ビット
;								1=アナログ入力
;								0=デジタルI/O
;			bit3	Unimplemented(read=0)
;			bit2-0	ANA2-0/RA2-0アナログ/デジタル選択ビット
;								1=アナログ入力
;								0=デジタルI/O
;			＊デフォルトでは、すべて1(アナログ入力)となっている
;
;		ANSELB(BANK3　18DH)
;			bit7-4	ANSC3-0/RC3-0　アナログ/デジタル選択ビット
;								1=アナログ入力
;								0=デジタルI/O
;			bit3-0	Unimplemented(read=0)
;			＊デフォルトではアナログ入力となっている
;
;		ANSELC(BANK3　18EH)　マニュアル131ページ
;			bit7-4	Unimplemented(read=0)
;			bit3-0	ANSC3-0/RC3-0　アナログ/デジタル選択ビット
;								1=アナログ入力
;								0=デジタルI/O
;			＊デフォルトではアナログ入力となっている
;
;		WPUA(BANK4　20CH)　ポートAプルアップ設定ビット
;			bit7-6	Unimplemented(read=0)
;			bit5-0			1=PORTA各ビットプルアップ有効
;					 _____	0=PORTA各ビットプルアップ無効
;					*WPUENビットが有効の時のみ、設定有効となる。
;
;		WPUB(BANK4　20DH)　ポートBプルアップ設定ビット
;			bit7-4			1=PORTB各ビットプルアップ有効
;					 _____	0=PORTB各ビットプルアップ無効
;			bit3-0	Unimplemented(read=0)
;					*WPUENビットが有効の時のみ、設定有効となる。
;
;		WPUC(BANK4　20EH)　ポートCプルアップ設定ビット
;			bit7-0			1=PORTC各ビットプルアップ有効
;					 _____	0=PORTC各ビットプルアップ無効
;					*WPUENビットが有効の時のみ、設定有効となる。
;
;		INLVLA(BANK7　38CH)　ポートA入力レベル設定レジスタ
;			bit7-6	Unimplemented(read=0)
;			bit5-0	RA5-0	ST/TTL選択ビット
;								1=シュミットトリガー(ST)入力
;								0=TTL入力
;
;		INLVLB(BANK7　38DH)　ポートB入力レベル設定レジスタ
;			bit7-4	RB7-4	ST/TTL選択ビット
;								1=シュミットトリガー(ST)入力
;								0=TTL入力
;			bit3-0	Unimplemented(read=0)
;
;		INLVLB(BANK7　38EH)　ポートC入力レベル設定レジスタ
;			bit7-0	RC7-0	ST/TTL選択ビット
;								1=シュミットトリガー(ST)入力
;								0=TTL入力
;
;	ADCON0レジスタ(BANK1　09DH)
;		bit7	Unimplemented(read=0)
;		bit6-2	CHS		アナログ入力チャンネル選択ビット
;						00000 = AN0/RA0
;						00001 = AN1/RA1
;						00010 = AN2/RA2
;						00011 = AN3/RA4
;						00100 = AN4/RC0
;						00101 = AN5/RC1
;						00110 = AN6/RC2
;						00111 = AN7/RC3
;						01000 = AN8/RC6
;						01001 = AN9/RC7
;						01010 = AN10/RB4
;						01011 = AN11/RB5
;						11101 = 温度インジケータ
;						11110 = DAC出力
;						11111 = FVRバッファ1出力
;		bit1	GO/DONE	A/D変換ステータスビット
;						1=変換開始指令（１にすると変換動作開始）
;						0=変換完了(変換完了すると０になる）
;		bit0	ADON	A/D変換ステータスビット
;						1=A/Dコンバータ動作
;						0=A/Dコンバータ停止
;
;	ADCON1レジスタ(BANK1　09EH)
;		bit7	ADFM	変換結果格納指定
;						1=右詰
;						0=左詰め
;		bit6-4	ADCS	A/D変換クロック選択ビット
;						000	= Fosc/2
;						001 = Fosc/8
;						010 = Fosc/32
;						011 = Frc
;						100 = Fosc/4
;						101 = Fosc/16
;						110 = Fosc/64
;						111 = Frc
;		bit3	Unimplemented(read=0)
;		bit2	ADNREF	参照負電圧指定
;						0 = VSS
;						1 = 外部VREF- (RA0)
;		bit1-0	ADPREF	参照正電圧指定
;						00 = VDD
;						01 = Reserved
;						10 = 外部VREF+ (RA1)
;						11 = 内部FVRモジュール
;
;		FVRCONレジスタ(BANK2　117H)
;			bit7	FVREN	FVRイネーブルビット
;							1有効、0無効
;			bit6	FVRRDY	FVR準備フラグビット(#1)書込み不可
;							1使用可能、0使用不可能あるいは禁止されている
;			bit5	TSEN	温度表示器イネーブルビット
;							1有効、0無効
;			bit4	TSRNG	温度表示器測定レンジ選択ビット
;							1=High Range:Vout=VDD-4VT
;							0=Low Range:Vout=VDD-2VT
;			bit3-2	CDAFVR	コンパレータとDACへのFVR電圧選択ビット
;							00 = FVR出力OFF
;							01 = FVR出力 1x(1.024V)
;							10 = FVR出力　2x(2.048V)#2
;							11 = FVR出力　4x(4.096V)#2
;			bit1-0	ADFVR	ADCへのFVR電圧選択ビット
;							00 = FVR出力OFF
;							01 = FVR出力 1x(1.024V)
;							10 = FVR出力　2x(2.048V)#2
;							11 = FVR出力　4x(4.096V)#2
;
;							#1)12F1824/16F1828では常に"1"
;							#2)FVR電圧出力はVDDを超える事は出来ない
;
;
;	OPTION_REG(BANK1　095H)
;				_____
;		bit7=1	WPUEN	プルアップ グローバル設定ビット
;						0=有効,1=無効
;		bit6=0	INTEDG	INTピン割り込み信号エッジ↑
;						1=↑
;						0=↓
;		bit5=1	TMR0CS	TMR0クロックソース選択ビット
;						1=外部入力RA2/T0CKI
;						0=内部システムクロック(Fosc/4)
;		bit4=0	TMR0SE	TMR0ソースエッジ選択ビット
;						1=RA2/T0CKIピンが↑の時インクリメント
;						0=RA2/T0CKIピンが↓の時インクリメント
;		bit3=0	PSA		プリスケーラ割当ビット
;						1=WDT
;						0=TMR0
;		bit2-0	PS		プリスケーラ分周比
;						000 1/2
;						001	1/4
;						010	1/8
;						011	1/16
;						100	1/32
;						101	1/64
;						110	1/128
;						111	1/256
;
;	CPSCON0(BANK0　01EH)
;		bit7=0	CPSON	CPSモジュール･イネーブルビット
;						1=有効
;						0=無効
;		bit6=0	CPSRM	静電容量式センシング参照電圧モードビット
;						1=CPSモジュールをHIレンジに設定
;						　　オシレータの参照電圧にDACとFVRを使用
;						0=CPSモジュールをLOWレンジに設定
;						　　オシレータ内蔵の参照電圧を使用
;		bit5-4	Unimplemented(read=0)
;		bit3-2	CPSRNG	静電容量式センシング電流レンジビット
;						CPSRM=0の場合
;						00=オシレータはOFF
;						01=オシレータをLOWレンジに設定、充放電電流は0.1uA
;						10=オシレータをMediumレンジに設定、充放電電流は1.2uA
;						11=オシレータをHighレンジに設定、充放電電流は18uA
;						CPSRM=1の場合
;						00=オシレータはON、ノイズ検出モード
;							充放電電流は供給されない
;						01=オシレータをLOWレンジに設定、充放電電流は9uA
;						10=オシレータをMediumレンジに設定、充放電電流は30uA
;						11=オシレータをHighレンジに設定、充放電電流は100uA
;		bit1=0	CPSOUT	静電容量式センシングオシレータ ステータスビット
;						1=オシレータが電流をソース（ピンから電流を出力）
;						0=オシレータが電流をシンク（ピンから電流を入力）
;		bit0=0	T0XCS	Timer0外部クロック源選択ビット
;						TMR0CS=1の場合
;						コア/Timer0モジュールのどの外部クロックからTimer0に
;						クロックを供給するかをTOXCSビットで制御する
;						1=Timer0のクロック源に静電容量式センシングオシレータ使用
;						0=Timer0のクロック源にT0CKIピンを使う
;						TMR0CS=0の場合
;						Timer0のクロック源にコア/Timer0モジュールで制御する
;						すなわち、Fosc/4
;
;
;		DACCON0レジスタ(BANK2　11AH)　
;		bit7	DACEN	DACイネーブルビット　P156 Fig17-1参照
;						1=許可
;						0=禁止
;		bit6	DACLPS	電圧指定
;						1=DAC出力電圧は+sourecと同等
;						0=DAC出力電圧は-sourceと同等
;		bit5	DACOE	DAC電圧出力イネーブルビット
;						1=DAC出力電圧をDACOUTピンに接続される
;						0=DAC出力電圧はDACOUTピンに接続されない
;		bit4	Un		Read as '0'
;		bit3-2	DACPSS	DAC Vsource+接続選択ビット
;						00 = VDD
;						01 = VREF+ピン(RA1)
;						10 = FVRバッファ2出力
;						11 = 使用不可
;		bit1-0	Un		Read as '0'
;
;
;
;
;	SSP1CON1	SSP制御レジスタ１	BSR=4
;		bit7	WCOL：書込みコリジョン検出ビット
;				マスタの場合
;				1=I2Cの送信開始条件が無効の時にSSP1BUFレジスタへ書込みが行われた
;				0=問題無
;				スレーブの場合
;				1=前のワードの送信中にSSP1BUFレジスタへの書き込みが行われた
;				0=問題無
;					*ソフトウエアでクリアする必要あり
;		bit6	SSP1OV：受信オーバーフロー インジケータービット(注1)
;				1=オーバーフロー発生
;				2=問題無
;					*ソフトウエアでクリアする必要あり
;		bit5	SSP1EN：同期シリアルポートイネーブルビット
;				1=シリアルポート有効(注2)
;				0=シリアルポート無効、I/Oポート使用可
;		bit4	CKP：クロック極性選択ビット
;				1=クロックを有効化
;				0=クロックをLOWに保持（クロックストレッチ）
;					*マスタモードでは使用しない
;		bit3-0  SSP1M：同期シリアルポート モード選択ビット
;				0110=スレーブモード、7ビットアドレス
;				0111=スレーブモード、10ビットアドレス
;				1000=マスターモード、クロック=FOSC/(4*SP1ADD+1))(注3)
;				1011=ファームウエア制御のマスターモード（スレーブアイドル）
;				1110=スレーブモード、7ビットアドレス、
;					スタートビットとストップビットの割込み有効
;				1111=スレーブモード、10ビットアドレス、
;					スタートビットとストップビットの割込み有効
;
;		注1)マスターモードの場合、新たな送受信はSSP1BUFへの書込みによって
;			開始するため、オーバーフロービットはセットされない
;		注2)SDAピンとSCLピンは入力としてTRIS=1設定
;		注3)SP1ADDの値、0,1,2はサポートされない
;
;	SSP1CON2	SSP制御レジスタ２
;		bit7	GCEN：ジェネラルコールイネーブルビット
;				1=SSP1SRでGCアドレス(00H)を受信した時の割込みを有効にする
;				0=GCアドレスを無効にする
;		bit6	ACKSTAT：肯定応答(ACK)ステータスビット
;				1=ACK受信した
;				0=ACK受信していない
;		bit5	ACKDT：ACKデータビット（受信モード）
;				1=ACKしない
;				0=ACKあり
;		bit4	ACKEN：ACKシーケンス イネーブルビット（マスタ受信モード）（注1）
;				1=ACKシーケンスを開始し、ACKDTビットを送信する
;				0=ACKシーケンスをアイドルにする
;		bit3	RCEN：受信イネーブルビット（マスターモードのみ）（注1）
;				1=受信モードを有効にする
;				0=受信をアイドルにする
;		bit2	PEN：ストップ条件イネーブルビット（注1）
;				SCK解放制御
;				1=ストップ条件を開始する、ハードウエアによって自動でクリアされる
;				0=ストップ条件をアイドルにする
;		bit1	RSEN：反復スタート条件イネーブルビット（注1）
;				1=反復スタート条件を開始する
;					ハードウエアによって自動でクリアされる
;				0=反復スタート条件をアイドルにする
;		bit0	SEN：スタート条件イネーブルビット（注1）
;				マスターモードの場合
;				1=スタート条件を開始する、ハードウエアによって自動でクリアされる
;				0=スタート条件をアイドルにする
;
;		注1）I2Cモジュールがアイドルで無い場合、これらのビットはセットされず、
;			 SSP1BUFに書き込まれない場合がある（SSP1BUFへの書込み無効）
;
;	SSP1CON3	SSP1制御レジスタ３
;		bit7	ACKTIM：肯定応答(ACK)タイムステータスビット（注1）
;				1=ACKシーケンスを実行中。
;				　SCLクロックの8番目の立下りエッジでセットされる
;				0=ACKシーケンスではない。
;				　SCLクロックの9番目の立上がりエッジでクリアされる
;		bit6	PCIE：ストップ条件割込みイネーブルビット
;				1=ストップ条件検出時の割込みを有効にする
;				0=ストップ条件検出時の割込みを無効にする
;		bit5	SCIE：スタート条件割込みイネーブルビット
;				1=スタート／リスタート条件検出時の割込みを有効にする
;				0=スタート条件検出時の割込みを無効にする
;		bit4	BOEN：バッファ上書きイネーブルビット
;				1=SSP1BUFは更新され、受信したアドレス／データバイトに対して
;				　ACK信号が生成される。
;				　BFビットが0の場合のみSSP1OVビットの状態を無視する。
;				0=SSP1OVがクリアされている時のみSSP1BUFが更新される
;				*マスタモードの場合、このビットは無視される
;		bit3	SDAHT：SDAホールド時間の選択ビット
;				1=SDAのホールド時間はSCLの立下りエッジから最小300ns
;				0=SDAのホールド時間はSCLの立下りエッジから最小100ns
;		bit2	SBCDE：スレーブモードのバスコリジョン検出イネーブルビット
;				1=スレーブバスコリジョン割込みを有効にする
;				0=スレーブバスコリジョン割込みを無効にする
;		bit1	AHEN：アドレスホールドイネーブルビット（スレーブモードのみ）
;				1=一致受信アドレスバイトのSCLの8番目の立下りエッジ後、SSP1CON1
;				　レジスタのCKPビットをクリアし、SCLがLOWに保持される
;				0=アドレスホールド機能を無効にする
;		bit0	DHEN：データホールドイネーブルビット（スレーブモードのみ）
;				1=受信データバイトのSCLの8番目の立下りエッジ後、スレーブハードウ
;				エアがSSP1CON1レジスタのCKPビットをクリアし、SCLがLOWに保持される
;				0=データホールド機能を無効にする
;		*注1）ACKTIMステータスビットがアクティブになるのは、AHENビットまたは、
;             DHENビットがセットされている場合のみ
;
;	SSP1MSK		SSP1マスクレジスタ
;		bit7-1	MSK：マスクビット
;				1=受信アドレスbitnをSSP1ADD(n)と比較して、I2Cアドレス一致を検出
;				0=受信アドレスbitnをI2Cアドレス一致の検出に使わない
;		bit0	I2Cスレーブモードのマスクビット、10ビットアドレス
;				I2Cスレーブモード、10ビットアドレス（SSP1M3-0=0111または1111)
;				1=受信アドレスbit0をSSP1ADD(0)と比較して、I2Cアドレス一致を検出
;				0=受信アドレスbit0をI2Cアドレス一致の検出に使わない
;				*スレーブモード、7ビットアドレスでは、このビットは無視される
;
;	SSP1ADD		MSSP1アドレス／ボーレートジェネレータ
;				マスターモードの場合
;		bit7-0	ADD：ボーレートクロック分周ビット（(ADD(7-0)+1)*4）/FOSC
;				スレーブモードの場合
;		bit7-1	ADD：7ビットのアドレス
;		bit0	未使用
;		*10ビットアドレスモードでの状態は割愛します
;
;	SSP1STAT	SSP1ステータスレジスタ
;		bit7	SMP：スルーレート制御
;				1=スルーレート制御の標準速度モード(100KHZ,1MHZ)を無効にする
;				0=スルーレート制御の高速モード(100KHZ)を有効にする
;		bit6	CKE：SMBus仕様互換入力
;				1=しきい値がSMBus仕様に準拠する入力
;				0=無効
;		bit5	D_NOT_A：データ/アドレスビット
;				1=最後に送受信したバイトがデータ
;				0=最後に送受信したバイトがアドレス
;		bit4	P：ストップビット
;				1=最後にストップビットが検出された事を示す
;				0=最後にストップビットが検出されなかった事を示す
;		bit3	S：スタートビット
;				1=最後にスタートビットが検出された事を示す
;				0=最後にスタートビットが検出されなかった事を示す
;		bit2	R_NOT_W：READ/WRITEビット情報
;				スレーブモード
;				1=読み出し
;				0=書込み
;				マスタモード
;				1=送信動作中
;				0=送信動作中で無い
;		*このビットとSEN,RSEN,PEN,RCEN,ACKENのどれかをORするとMSSP1がアイドル中
;		 かどうかが判る
;		bit1	UA：交信アドレスビット（10ビットアドレスモードのみ）
;				1=アドレスの更新が必要
;				0=アドレスの更新が不要
;		bit0	BF：バッファフル ステータスビット
;				受信
;				1=受信が完了、SSP1BUFがフルである
;				0=受信が完了していない、SSP1BUFがエンプティ
;				送信
;				1=データ送信中(ACK及びｽﾄｯﾌﾟﾋﾞｯﾄを含まない)SSP1BUFはフル
;				0=データ送信完了(ACK及びｽﾄｯﾌﾟﾋﾞｯﾄを含まない)SSP1BUFはエンプティ
;
;
;
;		INTCONレジスタ(#2)　コア　00BH
;			bit7	GIE		全割込制御
;							1許可、0禁止
;			bit6	PEIE	周辺装置割込制御
;							1許可、0禁止
;			bit5	TMR0IE	タイマ0割込許可制御
;							1許可、0禁止
;			bit4	INTE	RA2外部割込許可制御
;							1許可、0禁止
;			bit3	IOCIE	I/Oポート状態変化割込許可制御
;							1許可、0禁止
;			bit2	TMR0IF	タイマ0割込みフラグ(#1)
;							1オーバーフロー
;							0オーバーフローなし
;			bit1	INTF	RA2外部割込みフラグ(#1)
;							1割込み発生
;							0割込み発生なし
;			bit0	IOCIF	I/Oポート状態変化割込フラグ(#1)
;							1割込発生
;							0割込無
;
;							#1)ソフトウエアでリセット必要
;							#2)初期値=0なので、初期設定で0設定する必要は無い
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

init
;			各レジスタ初期設定(PIC16F1828)
			movlb	0h			;BANK0
			movlw	040h		;01000000B
			movwf	INTCON		;全割込みOFF、PEIE_ON
			movlb	01h			;BANK1
			bsf		PIE1,SSP1IE	;MSSP割込み有効
			;クロック設定
			movlb	01h			;BANK１に切替
			movlw	0f0h		;1111000B
			movwf	OSCCON		;内部発振器は8MHZに設定
								;4xPLL=ON
			;I/Oポート初期化
			movlb	0h			;BANK0
			clrf	PORTA		;Init PORT
			clrf	PORTB
			clrf	PORTC
			movlb	02h			;BANK2
			clrf	LATA		;出力ラッチレジスタ
			clrf	LATB
			clrf	LATC
			movlb	03h			;BANK3
			clrf	ANSELA		;RA0-7デジタルI/O
			clrf	ANSELB		;RB4-7デジタルI/O
			clrf	ANSELC		;RC0-7デジタルI/O
			movlb	01h			;BANK1
			movlw	0h			;TRISx=0は出力
			movwf	TRISA		;RA0-7出力
			movlw	050h		;50H=01010000B
			movwf	TRISB		;RB4,RB6入力(I2C)、RB5,RB7出力
			movlw	0h			;
			movwf	TRISC		;RC0-RC7出力

			;TMR0およびプルアップ設定
			movlb	01h			;BANK1
			movlw	0a7H		;10100111B
			movwf	OPTION_REG	;プルアップOFF
								;割込みエッジ↓
								;クロックソース外部
								;TMR0カウントエッジ↓
								;プリスケーラ割当→TMR0
								;プリスケーラ分周1/256にセット

			;ADC
;			movlb	01h			;BANK1
;			movlw	0E0h		;11100000B
;			movwf	ADCON1		;10bit変換、左詰め、基準電圧VDD
								;ADCクロック　Fosc/64=2us(32MHZ)

			;FVR
;			movlb	02h			;BANK2
;			movlw	082h		;10000010B
;			movwf	FVRCON		;FVRイネーブル
								;DACとCPSはOFF
								;ADCに4.096V
			;MSSP1
			movlb	04h			;BANK4
			movlw	050h
			movwf	SSP1CON3	;STOP検出割込み有効
			movlw	07ch		;I2Cアドレス 7CH(7bit 3EH+LSB(0))
			movwf	SSP1ADD		;
;			movlw	0FFH
;			movwf	SSP1MSK

;			設定終了
			movlb	0h



;			初期値セット
			clrf    hex0
			clrf    hex1
			clrf    hex2
			clrf    hex3
			bsf		PORTB,7		;LED_OFF

;
;		メイン プログラム
;
;

coldst
			movlw	0a0h		;
			movwf	BFAD0		;FIFOバッファアドレス初期値
			clrf	BFAD1		;BFAx=00A0H
			clrf	BFPT0		;バッファポインタ初期値
			clrf	BFPT1
			call	INIT_LCD	;SC1602B/D初期設定
			bsf		INTCON,GIE	;全割込み許可

;			goto	DEBUG03

;
;	コマンドワード（スレーブアドレスの後に送信される２バイト）
;		コントロールバイト＋データバイトで構成される
;
;	コントロールバイトのビット構成
;		ＣＯ＋ＲＳ＋下位６ｂｉｔ
;		CO:連続送信、最終送信の指定
;			CO=1連続コマンドワード
;			CO=0 最終コマンドワード
;		RS:データの属性
;			RS=1 液晶の表示データ
;			RS=0 液晶のインストラクションコード
;


;
;		I2C受信進行フラグ
;		MODE bit7-0
;		bit7	予約
;		bit6	予約
;		bit5	LCD_DATA
;					1=液晶データバイトを保留
;					0=コマンドワード受信継続中
;		bit4	LCD_INST
;					1=液晶コントロールバイトを保留
;					0=コマンドワード受信継続中
;		bit3	I2C_STOP
;					1=I2Cストップビットを検出
;					0=コマンドワード受信継続中
;		bit2	I2C_DATA
;					1=I2Cデータバイトを受信
;					0=データは無効
;		bit1	I2C_ADRESS
;					1=I2Cスレーブアドレスを受信
;					0=受信待ち、あるいは現在データは無効
;		bit0	I2C_START
;					1=I2Cスタートビットを検出
;					0=MSSP1はアイドル
;
;	START-ADRS-(CTRL-CMD-CTRL-DATA)-STOP or NEXT WORD
;
hotst
			call	MSSP_SLV		;MSSP1起動
			clrf	MODE
;		I2Cアドレス受信待ち
LV11		btfsc	MODE,3			;STOP_BIT
			goto	LV31			;MSSP1ディセーブル
			btfss	MODE,1			;I2Cアドレス受信フラグ
			bra		LV11			;LV1ループ

;		コントロールバイト受信待ち
LV21		btfsc	MODE,3			;ストップビット検出フラグ
			goto	LV31			;MSSP1ディセーブル
			btfss	MODE,2			;I2C_DATA受信フラグ
			bra		LV21			;LV2ループ
;		コントロールバイト処理　(CO+RS+000000)
;			C0H=連続コマンドワード、次の受信は液晶の表示データ
;			80H=連続コマンドワード、液晶のインストラクションコード
;			40H=最終コマンドワード、液晶の表示データ
;			00H=最終コマンドワード、液晶のインストラクションコード

			movf	I2C_DATA,W		;受信I2Cデータ
			movwf	CTRL			;CTRL_BYTEとして保存
			movlw	0c0h
			xorwf	CTRL,W
			btfsc	STATUS,Z
			goto	LV25			;C0H=連続コマンド表示データ
			movlw	080h
			xorwf	CTRL,W
			btfsc	STATUS,Z
			goto	LV24			;80H=連続コマンドインストラクション
			movlw	040h
			xorwf	CTRL,W
			btfsc	STATUS,Z
			goto	LV23			;40H=最終コマンド表示データ
;			goto	LV22			;00Hとみなす、最終インストラクション

;
;		CTRL=00H:最終コマンド インストラクションコード待ち
;
LV22
			bcf		MODE,2			;I2C_DATAフラグクリア
			bcf		MODE,4			;LCD_INSTフラグクリア
			btfss	MODE,2			;I2C_DATA受信フラグ
			bra		$-1				;受信待ち
;
			movf	I2C_DATA,W		;I2C_DATAはLCD_INSTとみなす
			bcf		MODE,2			;I2C_DATAフラグクリア
;			call	CHK_CMD			;LCD_INSTチェック・変更
			call	SEND_CMD		;Wreg=液晶命令
			goto	LV21			;次のI2C_DATA受信へ

;
;		CTRL=40H:最終コマンド液晶データバイト待ち			
;
LV23
			bcf		MODE,2			;I2C_DATAフラグクリア
			bcf		MODE,5			;LCD_DATAフラグクリア
			btfss	MODE,2			;I2C_DATAフラグ
			bra		$-1
;
			movf	I2C_DATA,W		;I2C_DATAはLCD_DATAとみなす
			bcf		MODE,2			;I2C_DATAフラグクリア
			call	SEND_DATA
;
			clrf	MODE			;受信終了かも知れない
			goto	LV21			;I2C_DATA受信待ち

;
;		CTRL=80H:連続コマンド インストラクションコード待ち
;
LV24		bcf		MODE,2			;I2C_DATAフラグクリア
			bcf		MODE,4			;LCD_INSTフラグクリア
			btfss	MODE,2			;I2C_DATAフラグ
			bra		$-1				;I2C_DATA受信待ち
;
			movf	I2C_DATA,W		;I2C_DATAはLCD_INSTとみなす
			bcf		MODE,2			;I2C_DATAフラグクリア
;			call	CHK_CMD
			call	SEND_CMD		;Wreg=液晶命令
			bsf		MODE,4			;LCD_INSTフラグセット
			goto	LV21			;次のI2C_DATA受信へ

;
;		CTRL=C0H:連続コマンド データコード待ち
;
LV25		bcf		MODE,2			;I2C_DATAフラグクリア
			bcf		MODE,5			;LCD_DATAフラグクリア
			btfss	MODE,2			;I2C_DATA待ち
			bra		$-1
;
			movf	I2C_DATA,W		;I2C_DATAはLCD_DATAとみなす
			bcf		MODE,2			;I2C_DATAフラグクリア
			call	SEND_DATA		;Wreg=液晶表示データ
			bsf		MODE,5			;LCD_DATAフラグセット
			goto	LV21			;次のI2C_DATA受信へ

;
;			受信終了、MSSP1リセット
;
LV31		movlb	04h
			bsf		SSP1CON1,SSPEN
			clrf	MODE
			goto	hotst

			
;
;	I2C受信用デバッグ プログラム
;
;		受信したI2C_DATAをLCDに表示
;		1行目	I2C_DATA
;				ASCIIに返還後表示
;		2行目	ステータス
;				I2C_START(LEDにする？）やI2C_STOP、他
;
DEBUG03
			call	MSSP_SLV		;MSSP1起動
			clrf	MODE

;		I2Cアドレス受信待ち
DBL11		btfsc	MODE,3			;STOP_BIT
			goto	DBL31			;MSSP1ディセーブル
			btfss	MODE,1			;I2Cアドレス受信チェック
			bra		DBL11

;		I2C DATA 受信待ち
DBL21		btfsc	MODE,3			;ストップビット検出
			goto	DBL31			;
			btfss	MODE,2			;I2Cデータ受信チェック
			bra		DBL21			;I2Cデータ受信待ちループ
			movf	I2C_DATA,W		;受信I2Cデータ

;		I2CデータをASCIIに変換、LCDへ出力
			movlb	0h
			call	NUTOASC
			bcf		MODE,2			;I2C_DATAフラグクリア
			movlw	080h
			call	SEND_CMD		;Wreg=液晶命令
			call	wait50u
			movf	DBUF1,W
			call	SEND_DATA
			call	wait50u
			movlw	081h
			call	SEND_CMD
			call	wait50u
			movf	DBUF0,W
			call	SEND_DATA
			goto	DBL21			;次のI2C_DATA受信へ


;			受信終了、MSSP1リセット
DBL31		movlb	04h
			bsf		SSP1CON1,SSPEN
			clrf	MODE
			goto	DEBUG03

			
			
			
			
			
			
			
			
			;デバッグ１
DEBUG01
			movlw	LOW MSG01	;MSG01間接アドレス値下位8ビット
			movwf	MSAD0
			movlw	HIGH MSG01	;MDG01間接アドレス値上位8ビット
			movwf	MSAD1
			call	CLRLCD		;LCD画面全クリア
			call	PUTL1		;LCD1行目にMSG01の内容を連続書込み
			call	wait1s
			movlw	LOW MSG02
			movwf	MSAD0
			movlw	HIGH MSG02
			movwf	MSAD1
			call	PUTL2		;LCD2行目に連続書込み
			call	wait1s
			call	wait1s

			movlw	LOW MSG03
			movwf	MSAD0
			movlw	HIGH MSG03
			movwf	MSAD1
			call	CLRLCD
			call	PUTL1
			call	wait1s
			movlw	LOW MSG04
			movwf	MSAD0
			movlw	HIGH MSG04
			movwf	MSAD1
			call	PUTL2
			call	wait1s
			call	wait1s
			goto	DEBUG01


MSG01		DT		"HELLO! CQ CQ CQ"
			DW		0			;エンドコード
MSG02		DT		"This is JA0QON"
			DW		0
MSG03		DT		"ﾆｲｶﾞﾀ ｹﾝ ﾀｲﾅｲｼ"
			DW		0h
MSG04		DT		"ﾎﾝｼﾞﾂﾊ ﾖｲｵﾃﾝｷﾃﾞｽ"
			DW		0h

DEBUG02		;FIFOバッファテスト
			movlw	0ffh
			call	FIFO_IN
			movlw	0cbh
			call	FIFO_IN
			movlw	0bah
			call	FIFO_IN
			movlw	0ach
			call	FIFO_IN
			movlw	09ah
			call	FIFO_IN
			movlw	089h
			call	FIFO_IN
			movlw	077h
			call	FIFO_IN
			movlw	065h
			call	FIFO_IN

			call	FIFO_OUT
			call	FIFO_OUT
			call	FIFO_OUT
			call	FIFO_OUT
			call	FIFO_OUT
			call	FIFO_OUT
			call	FIFO_OUT
			call	FIFO_OUT

			goto	DEBUG02


;
;	ＦＩＦＯバッファ
;
;	入力	FIFO_IN
;			Wregにデータを入れてコールする事
;
;	出力	FIFO_OUT
;			Wregにデータを入れてリターンする
;
;	実アドレスエリア	
;			A0H-BFHの３２バイト
;
;	先頭アドレス指定
;			BFA0,BFA1に格納
;
;	深度ポインタ
;			BFPTに格納
;
;	使用ワーク
;			LDWR	Wreg保存
;			BFPT0	バッファ内専用ポインタ新規入力位置
;			BFPT1	バッファ内専用ポインタ処理用
FIFO_IN
			movwf	LDWR		;push_Wreg
			movf	BFAD0,W		;バッファアドレス下位8bit
			movwf	FSR0L
			movf	BFAD1,W		;上位8bit
			movwf	FSR0H
			movf	BFPT0,W		;入力ポインタ
			addwf	FSR0L,F		;最後尾実アドレス
			movf	LDWR,W		;pop_Wreg
			movwf	INDF0		;バッファに送信
			incf	BFPT0,F		;ポインタ更新、次の入力位置を示す
			return
;
FIFO_OUT
			movf	BFPT0,W		;入力ポインタのゼロチェック
			iorlw	0h
			btfsc	STATUS,Z
			retlw	0h			;データ無なので何もしない
;
			clrf	BFPT1
			movf	BFAD0,W		;バッファ先頭アドレス下位8bit
			movwf	FSR0L
			movf	BFAD1,W		;上位8bit
			movwf	FSR0H
fio01		movf	INDF0,W
			movwf	LDWR		;引数保存
;			減数処理
fio02		incf	FSR0L,F		;転送元アドレス
			incf	BFPT1,F
			movf	BFPT0,W
			xorwf	BFPT1,W		;一致で0
			btfsc	STATUS,Z
			bra		fio03		;転送終了
;
			movf	INDF0,W
			decf	FSR0L,F		;転送先アドレス
			movwf	INDF0
;
			incf	FSR0L,F
			bra		fio02
;
fio03
			decf	FSR0L,F
			decf	BFPT0,F
			movlw	0h
			movwf	INDF0		;00Hで消去、アドレス解放
			movf	LDWR,W
			return

fioef		retlw	00h			;処理エラー発生、戻し値は意味無
			

;
;	ＭＳＳＰモジュール　Ｉ２Ｃモード制御サブルーチン
;
;
;	PIC16F1828
;   I2C　スレーブモード初期化サブルーチン
;
;		RB6		SCL			I2Cクロック
;		RB4		SDA			I2Cデータ
;		TRISB	RB4,RB6はデジタル入力モードに設定

MSSP_SLV
			movlb   04h			;BANK4
			movlw   036h		;36H=00110110
			movwf   SSP1CON1	;SSP1イネーブル
								;シリアルポート有効化
								;クロック有効
								;I2Cスレーブモード、7ビットアドレス
			clrf	BSR
			return

　
;
;       ＬＣＤ　ＤＩＳＰＬＡＹ　ＳＣ１６０２Ｂ／Ｄ
;
;       書込みサブルーチン群
;
;       Set DDRAM address = RS=0 + R/W=0 + DB7=1,DB6-DB0=00H-4FH
;		Write data to RAM = RS=1 + R/W=0 + DB7-DB0=CGRAM or DDRAM data
;                   RS=1の時、液晶の表示データあるいはCGRAMのデータ
;                   RS=0の時、液晶のインストラクションコード
;                   R/W=1の時、データ読込み
;                   R/W=0の時、データ書込み
;       コマンド間には37us以上、あるいは1.52ms以上のウエイトが必要
;
;       DSP_ADR     80H-8FH 1行目　表示位置アドレス(DDRAM)
;                   C0H-CFH 2行目　同じ
;					※これは機能ビット(DB7=1)+DDRAMアドレスで表現されている

;
;   ＬＣＤにＷレジスタのアスキーコードを単発で書き込む
;
;		コマンドワードはアドレス8bit＋表示データ8bitで構成
;		表示位置指定	DSP_ADRに入れて呼び出す
;
PUTW
			movwf	icw0		;PUSH Wreg
			movf	DSP_ADR,W	;表示アドレス
			call	SEND_CMD
            call    wait50u
			movf	icw0,W		;POP Wreg
			call	SEND_DATA	;表示キャラクタコード（アスキーコード）
			call	wait50u
			return
;
;	指定のデータをＬＣＤ1行目に先頭から連続書込み
;
;		MSAD0	指定データ格納アドレス下位8ビット
;		MSAD1	指定データ格納アドレス上位7ビット
;
PUTL1
			movlw	080h		;1行目DDRAM先頭アドレス
			movwf	DSP_ADR		;DDRAMアドレス
			movf	MSAD0,W
			movwf	FSR0L
			movf	MSAD1,W
			movwf	FSR0H

PTL11
			movf	INDF0,W		;MSGアドレスよりデータを取得
			iorlw	0h			;エンドコードチェック
			btfsc	STATUS,Z
			bra		PTL12		;end of msg
			call	PUTW		;コマンドワード送信（W=DATA、DSP_ADR=CMD）
			incf	FSR0L,F
			incf	DSP_ADR,F
			movlw	090h		;データアドレス オーバー
			xorwf	DSP_ADR,W
			btfss	STATUS,Z
			bra		PTL11
PTL12		return				;
;
;	指定のデータをＬＣＤ2行目に連続書込み
;
;		MSAD0	データアドレス下位8ビット
;		MSAD1	データアドレス上位7ビット
;
PUTL2
			movlw	0c0h		;２行目DDRAM先頭アドレス
			movwf	DSP_ADR		;DDRAMアドレス
			movf	MSAD0,W
			movwf	FSR0L
			movf	MSAD1,W
			movwf	FSR0H

PTL21
			movf	INDF0,W		;MSGアドレスよりデータを取得
			iorlw	0h			;エンドコードチェック
			btfsc	STATUS,Z
			bra		PTL22		;end of msg
			call	PUTW		;コマンドワード送信（W=DATA、DSP_ADR=CMD）
			incf	FSR0L,F
			incf	DSP_ADR,F
			movlw	0d0h		;データアドレス オーバー
			xorwf	DSP_ADR,W
			btfss	STATUS,Z
			bra		PTL21
PTL22		return				;

;
;	Ｗｒｅｇのキャラクタデータをチェック
;	ヌルデータはスペース(20H)に置き換える
;
CKCW
			iorlw	0h
			btfsc	STATUS,Z
			retlw	020h
			return
;
;		ＬＣＤ画面オールクリア
;
CLRLCD
			movlw	01h			;画面クリアコマンド
			call	SEND_CMD
			call	wait5m
			return

;
;		ＬＣＤ１行目クリア
;
CCR1


;
;       ＳＣ１６０２Ｂ／Ｄイニシャライズ
;			８ビットモード用
;
;		16桁2行ノーマルフォント
;
INIT_LCD
			call	wait100m	;LCDパワーオン ウエイト
			movlw	038h		;ファンクションセット　8bitモード
			call	SEND_CMD	;
			call	wait50u
			movlw	038h		;ファンクションセット　8bitモード
			call	SEND_CMD	;
			call	wait50u
;			Display on / Cursor off
            movlw   0ch			;Display on、カーソルOFF、
            call    SEND_CMD	;カーソル ブリンクOFF
            call    wait50u
;			Display clear
            movlw   01h         ;クリアコマンド
            call    SEND_CMD
            call    wait5m
;			Entry mode set
            movlw   06h			;右インクリメント、表示シフトOFF
            call    SEND_CMD
            call    wait5m
            return

;
;		ＳＣ１６０２Ｂ／Ｄ　低レベル サブルーチン
;
;		使用ポート
;		RA5=Enable（L-H-L)
;		RA4=R/W
;			1=読み出し
;			0=書込み
;		RA2=RSレジスタ選択
;			1=データレジスタ
;			0=制御レジスタ
;		RC7-0=DB7-0
;
;		送信
;		事前にWregに8ビットデータを用意して呼び出し
;
;		8bitモード データ送信シークェンス
;
;		(1)DB7-DB0を提示（RC7-RC0)
;		(2)R/W=0（RA4)
;		(3)RS=1(RA2)
;		(4)ｳｪｲﾄ40ns以上
;		(5)E=0からE=1(RA5)
;		(6)ｳｪｲﾄ230ns以上
;		(7)E=1→E=0(RC2)
;		(8)ｳｪｲﾄ10ns以上
;		(9)RS=0
;
;
;		使用ワーク
;			wrk0	データ保存

;
;		Ｗレジスタの8ビット分送出（8bitモード）
;
SEND_DATA	;データ送信
			movwf	wrk0		;push Wreg
			bcf		PORTA,5		;E=0
			call	SET_RSC		;R/W=0(WRITE)、RS=0(COMMAND)
			call	w10u		;オフセット（RS=R/W=E=0)
			movf	wrk0,W		;pop Wreg
			movwf	PORTC		;データ提示
			call	w10u		;
			bsf		PORTA,2		;RS=1(データモード選択)
			call	w10u
			bsf		PORTA,5		;E=1（データ イネーブル）
			call	w10u
			bcf		PORTA,5		;E=0
;			call	wait50u
			return

SEND_CMD	;コマンド送信
			movwf	wrk0		;push Wreg
			bcf		PORTA,5		;E=0
			call	SET_RSC		;R/W=0(WRITE)、RS=0(COMMAND)
			call	w10u		;オフセット（RS=R/W=E=0)
			movf	wrk0,W		;pop Wreg
			movwf	PORTC		;データ提示
			call	w10u		;
			bsf		PORTA,5		;E=1（データ イネーブル）
			call	w10u
			bcf		PORTA,5		;E=0
;			call	wait50u
			return


;
;		ＬＣＤ制御ビット
;
SET_RSC		;制御レジスタ選択
			bcf		PORTA,2		;RS=0 制御レジスタを選択
			nop
			bcf		PORTA,4		;R/W=0 書込みモードセット
			return
SET_RSD		;データレジスタ選択
			bsf		PORTA,2		;RS=1 データレジスタを選択
			nop
			bcf		PORTA,4		;R/W=0 書込みモードセット
			return

;
;		16進8bitバイナリ数値をASCIIコードに変換
;
;		入力	Wreg:00H-FFH
;		出力	DBUF0:下位4bit分のASCIIコード
;			DBUF1:上位4bit分のASCIIコード
NUTOASC
			movwf	LDWR		;Wreg退避
			andlw	0fh
			addlw	030h
			movwf	DBUF0
			;
			swapf	LDWR,W
			andlw	0fh
			addlw	030h
			movwf	DBUF1
			return
			

;
;			32ビットバイナリ10倍演算(符号無整数)
;
;		入力	hex(0-3)	32ビット
;		出力	hex(0-3)
;
;		使用ワーク	hexw0-3	4バイト
;

MLT32_X10
;			データ保存
			movf	hex0,W
			movwf	hexw0
			movf	hex1,W
			movwf	hexw1
			movf	hex2,W
			movwf	hexw2
			movf	hex3,W
			movwf	hexw3

;			32ビットデータを8倍
			bcf		STATUS,C	;
			rlf		hex0,F		;2倍を3回実行する
			rlf		hex1,F
			rlf		hex2,F
			rlf		hex3,F
			bcf		STATUS,C	;
			rlf		hex0,F
			rlf		hex1,F
			rlf		hex2,F
			rlf		hex3,F
			bcf		STATUS,C
			rlf		hex0,F
			rlf		hex1,F
			rlf		hex2,F
			rlf		hex3,F

			call	ADD32B		;元データを加算
			call	ADD32B


			btfss	STATUS,C	;オーバーフローか？
			retlw   0h
            retlw   01h

;
;       16ビットバイナリ　4倍演算（符号無整数)
;
;       hex0,hex1=(hex0,hex1)*2
;		W=0の時、正常終了
;		W=1の時、エラー発生、演算結果は保障されない
;
MLT16_X4
            bcf     STATUS,C    ;Cフラグクリア
            rlf     hex0,F      ;左ローテート（下位8ビット×２）
            rlf     hex1,F      ;左ローテート（上位8ビット×２）
            btfsc   STATUS,C
            retlw   01h         ;演算オーバーフロー発生
            rlf     hex0,F      ;左ローテート（下位8ビット×２）
            rlf     hex1,F      ;左ローテート（上位8ビット×２）
            btfss   STATUS,C
            retlw   0h          ;演算正常終了
            retlw   01h         ;演算オーバーフロー発生


;			32ビットバイナリ加算(整数符号無）
;
;		事前に(hex0-3)、(hexw0-3)に数値を入れておく事
;		演算結果でエラー(桁上がり）が発生しても対処はしない
;
;		演算
;		hex(0-3) = hex(0-3) + hexw(0-3)
;

ADD32B
			movf	hexw0,W		;hex0=hex0+hexw0
			addwf	hex0,F		;桁上がりでC=1
			movlw	01h			;この命令はフラグ変化しない
			btfss	STATUS,C	;if c=1 then hex1=hex1+1
			goto	ad31		;桁上がり無
;			(hex0+W)に桁上がり発生、処理
			addwf	hex1,F		;hex1=hex1+1
			btfsc	STATUS,C	;桁上がり無なら、goto ad31
			addwf	hex2,F		;桁上がり発生、hex2=hex2+1
			btfsc	STATUS,C	;桁上がり無なら、goto ad31
			addwf	hex3,F		;桁上がり発生、hex3=hex3+1
								;ここで桁上がり発生しても対処しない
ad31		movf	hexw1,W
			addwf	hex1,F
			movlw	01h
			btfsc	STATUS,C
			addwf	hex2,F
			btfsc	STATUS,C
			addwf	hex3,F

ad32		movf	hexw2,W
			addwf	hex2,F
			movlw	01h
			btfsc	STATUS,C
			addwf	hex3,F
			movf	hexw3,W
			addwf	hex3,F
			retlw	0h


;
;
;			32ビットバイナリ減算(整数符号無)
;
;		事前にhex(0-3)、hexw(0-3)に数値を入れておく事
;		演算結果でエラー(マイナス）の場合W=1、OKの時はW=0でリターン
;		W=1の場合、演算結果は保障されない
;
;		演算
;		hex(0-3) = hex(0-3) - hexw(0-3)
;

SUB32B
;			hex0-hexw0の減算
			movf	hexw0,W		;hex0=hex0-W(hexw0)
			subwf	hex0,F		;W>HEX0の時、ボロー(C=0)
								;W<=HEX0の時、無(C=1)
			movlw	01h			;この命令はフラグ変化しない
			btfss	STATUS,C	;C=1なら、hex1-hexw1へ
;			(hex0-W)にボロー発生、hex1に桁借り処理
			subwf	hex1,F		;hex1=hex1-1
			btfss	STATUS,C	;C=1なら、goto sb31
			subwf	hex2,F		;(hex1-1)にボロー発生、hex2に桁借り
			btfss	STATUS,C	;C=1なら、goto sb31
			subwf	hex3,F		;(hex2-1）ボロー発生、hex3に桁借り
			btfss	STATUS,C
			retlw	01h			;hex3にボロー発生、エラー終了

;			hex1-hexw1の減算
sb31		movf	hexw1,W		;
			subwf	hex1,F
			movlw	01h
			btfss	STATUS,C
			subwf	hex2,F
			btfss	STATUS,C
			subwf	hex3,F
			btfss	STATUS,C
			retlw	01h
;			hex2-hexw2の減算
			movf	hexw2,W
			subwf	hex2,F
			movlw	01h
			btfss	STATUS,C
			subwf	hex3,F
			btfss	STATUS,C
			retlw	01h
;			hex3-hexw3の減算
			movf	hexw3,W
			subwf	hex3,F
			btfss	STATUS,C
			retlw	01h
			retlw	0h

;		16ビットバイナリ加算
;		hex(0-1)=hex(0-1)+hexw(0-1)
;		W=0の時、正常終了
;		W=1の時、エラー発生（キャリー）、演算結果は保障されない
ADD16B
			movf	hexw0,W		;W=hexw0
			addwf	hex0,F		;hex0=hex0+hexw0
			btfss	STATUS,C
			goto	ad11		;キャリー無で次の加算
			incf	hex1,F		;キャリー発生、hex1=hex1+1
			btfsc	STATUS,C
			retlw	01h			;キャリー発生、加算エラー終了
ad11		movf	hexw1,W		;W=hexw1
			addwf	hex1,F		;hex1=hex1+hexw1
			btfsc	STATUS,C
			retlw	01h			;キャリー発生、加算エラー終了
			retlw	0h			;加算正常終了


;		16ビットバイナリ減算
;		hex(0-1)=hex(0-1)-hexw(0-1)
;		W=0の時、正常終了
;		W=1の時、エラー発生（ボロー）、演算結果は保障されない
SUB16B
			movf	hexw0,W		;W=hexw0
			subwf	hex0,F		;hex0=hex0-hexw0
			movlw	01h			;フラグ変化しない
			btfsc	STATUS,C
			goto	sb11		;ボロー無で次の減算
			subwf	hex1,F		;ボロー発生、hex1=hex1-1
			btfss	STATUS,C
			retlw	01h			;ボロー発生、減算エラー終了

sb11		movf	hexw1,W		;W=hexw1
			subwf	hex1,F		;hex1=hex1-hexw1
			btfss	STATUS,C
			retlw	01h			;ボロー発生、減算エラー終了
			retlw	0h			;減算正常終了


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
;		４バイトバイナリの10桁BCDへの変換
;		MicroChip社のアプリケーションノートより
;
;		入力		4バイト(32ビット)16進バイナリ
;				hex0
;				hex1
;				hex2
;				hex3
;
;		出力		5バイト(10桁)ＢＣＤ
;				digit12
;				digit34
;				digit56
;				gidit78
;				gidit9A
;
;		使用ワーク
;				hexw0	入力データ保存用
;				hexw1
;				hexw2
;				hexw3
;				shift	シフトカウンタ
;				bcdw0	補正処理ワーク
;				bcdw1
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
BCD
			BCF		STATUS,C	;キャリーリセット
			MOVLW	020H		;シフトカウンタ初期化
			MOVWF	shift		;4バイト分32回の指定
			CLRF	digit12		;BCDデータエリア初期化
			CLRF	digit34
			CLRF	digit56
			CLRF	digit78
			CLRF	digit9A
			movf	hex0,W
			movwf	hexw0
			movf	hex1,W
			movwf	hexw1
			movf	hex2,W
			movwf	hexw2
			movf	hex3,W
			movwf	hexw3

			;変換ループ処理
loop
			RLF		hexw0,F		;16進データ左シフト
			RLF		hexw1,F
			RLF		hexw2,F
			RLF		hexw3,F
			RLF		digit12,F	;BCDデータ左シフト
			RLF		digit34,F
			RLF		digit56,F
			RLF		digit78,F
			RLF		digit9A,F
			DECFSZ	shift,F		;
			GOTO	adjst		;BCD調整処理へ
			RETURN

			;BCDデータ全桁補正処理
adjst
			MOVF	digit12,W	;digit12
			CALL	adjbcd
			MOVWF	digit12
			MOVF	digit34,W	;digit34
			CALL	adjbcd
			MOVWF	digit34
			MOVF	digit56,W	;digit56
			CALL	adjbcd
			MOVWF	digit56
			MOVF	digit78,W	;digit78
			CALL	adjbcd
			MOVWF	digit78
			MOVF	digit9A,W	;digit9A
			CALL	adjbcd
			MOVWF	digit9A
			GOTO	loop

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
;			1バイト2桁分必要に応じて+3補正処理
;
;			入力		W_reg
;			出力		W_reg
;
;			使用ワーク	bcdw0
;					bcdw1
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
adjbcd
			MOVWF	bcdw0		;元データをbcdw0に保存
			MOVLW	3			;W=3
			ADDWF	bcdw0,W		;W=3+bcdw0
			MOVWF	bcdw1		;下桁を+3した上下桁をbcdw1に保存
			BTFSC	bcdw1,3		;if 下桁<7 then next_skip
			MOVWF	bcdw0		;下桁を+3した上下桁をbcdw0に保存

			MOVLW	030H		;W+30
			ADDWF	bcdw0,W		;W=上桁+3
			MOVWF	bcdw1		;それをいったんbcdw1に保存
			BTFSC	bcdw1,7		;if 上桁<7 then next_skip
			MOVWF	bcdw0		;上桁を+3した上下桁をbcdw0に保存
			MOVF	bcdw0,W		;W_regに入れてリターン
			RETURN


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
;			遅延時間サブルーチン	32MHZ用
;
;		1cycle	= 0.125us
;		使用レジスタ	= cnt2,cnt3
;		BSR		=0(BANK0)
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

wait100u						;呼び出しも含めて、100us
								;call is 2cycles
			movlw	09h			;1
			movwf	cnt2		;1
			movlb	0h
			nop
			nop					;3
w100u		nop					;
			call	w10u		;10*9=90us(ここだけ命令ステップを数えない）
			decfsz	cnt2,F		;4*8+3=31cycles
			goto	w100u
			return				;2+5+31+2=40cycles=20us

wait50u							;呼び出しも含めて、50us
			call	wait25u
wait25u							;呼び出しも含めて、25us
			call	w10u
			call	w10u
			movlw	0bh			;5us=0.125us*40cycles
			movwf	cnt2		;
w25u		decfsz	cnt2,F		;ループ 2+10*3+2=34cycles
			goto	w25u
			nop
			nop
			return				;2+34+2+2=40cycles=5us

wait5m							; 5ms
			movlb	0h
			movlw	05h
			movwf	cnt2
w5m			call	w1m
			decfsz	cnt2,F
			goto	w5m
			return

wait10m							; 10ms
			movlb	0h
			movlw	d'10'
			movwf	cnt2
w10m		call	w1m
			decfsz	cnt2,F
			goto	w10m
			return

wait20m							; 20ms
			movlb	0h
			movlw	d'20'
			movwf	cnt2
w20m		call	w1m
			decfsz	cnt2,F
			goto	w20m
			return
wait50m							; 50ms
			movlb	0h
			movlw	d'50'
			movwf	cnt2
w50m		call	w1m
			decfsz	cnt2,F
			goto	w50m
			return

wait100m						; 100ms
			movlb	0h
			movlw	d'100'
			movwf	cnt2
w100m		call	w1m
			decfsz	cnt2,F
			goto	w100m
			return

wait500m						; 500ms
			movlb	0h
			movlw	05h
			movwf	cnt3
w500m		call	wait100m
			decfsz	cnt3,F
			goto	w500m
			return

wait1s							; 1s
			movlb	0h
			movlw	d'10'
			movwf	cnt3
w1s			call	wait100m
			decfsz	cnt3,F
			goto	w1s
			return

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
;			1ms 基本ウェイト
;			呼び出しを含めて1msとなる。
;
;		clock	= 32MHz(0.03125usec)
;		1cycle	= 0.125usec
;		1ms		= 0.125usec * 8000cycles
;
;			使用変数　cnt0,cnt1
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
w1m
			movlb	0h
			movlw	08h
			movwf	cnt0		;
;			外周ループ
w1m0		movlw	0c7h		;199d
			movwf	cnt1		;
;			内周ループ
w1m1		nop					;
			nop					;5cycles*cnt1
			decfsz	cnt1,F		;2+5*198+4=996c/s
			goto	w1m1		;
;
			decfsz	cnt0,F		;
			goto	w1m0		;2+7*999+998=7993cycles
			nop
			return					;other=(3+4)cycles
									;Total 8000*0.125us=1ms


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
;			10us 基本ウェイト
;			呼び出し（call　w10u)も含めて、10usとなる。
;
;		clock	= 32MHZ(0.03125us)
;		1cycle	= 0.125us
;		10us	= 0.125us * 80cycles
;		使用変数　cnt0,cnt1
;		'goto','call','return'は2サイクル消費する
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

w10u
			movlb	0h
			movlw	018h		;18H=24
			movwf	cnt0		;
w10u0		decfsz	cnt0,F		;3*23+2=71
			goto	w10u0		;
			nop
			nop
			return				;2+3+71+2+2=80cycles

w05u
			movlw	0bh			;5us=0.125us*40cycles
			movwf	cnt0		;
w05u0		decfsz	cnt0,F		;ループ 2+3*10+2=34cycles
			goto	w05u0
			nop
			nop
			return				;2+34+2+2=40cycles=5us

w02u
			movlw	04h			;2us=0.125us*16cycles
			movwf	cnt0		;
w02u0		decfsz	cnt0,F		;2+3*3+2+1+2=16cycles
			goto	w02u0
			nop
			return				;
w01u
			nop					;1us=0.125us*8cycles
			nop					;2+4+2=8cycles
			nop
			nop
			return

;

;
            END

